[arch-commits] Commit in drumstick/trunk (PKGBUILD)

[David Runge]

    Date: Thursday, January 7, 2021 @ 10:42:11
  Author: dvzrv
Revision: 811559

upgpkg: drumstick 2.0.0-1: Upgrade to 2.0.0.

Update url to TLS.
Add only direct dependencies in depends.
Add all sodeps in package() and the respective packages to makedepends.
Remove all optdepends (they are covered by the sodeps).
Update provides to include libdrumstick-widgets.so as well.
Remove prepare() as the fix for fluidsynth detection is not required anymore.
Apply latest cmake packaging guidelines.
File upstream ticket about failing tests.
Update maintainer info.

Modified:
  drumstick/trunk/PKGBUILD

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++----------------------
 1 file changed, 25 insertions(+), 22 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2021-01-07 10:41:45 UTC (rev 811558)
+++ PKGBUILD	2021-01-07 10:42:11 UTC (rev 811559)
@@ -1,41 +1,44 @@
-# Maintainer: David Runge <dave at sleepmap.de>
+# Maintainer: David Runge <dvzrv at archlinux.org>
 # Contributor: speps <speps at aur dot archlinux dot org>
 # Contributor: Dany Martineau <dany.luc.martineau at gmail.com>
 
 pkgname=drumstick
-pkgver=1.1.3
-pkgrel=3
+pkgver=2.0.0
+pkgrel=1
 pkgdesc="MIDI libraries for Qt5/C++"
 arch=('x86_64')
-url="http://drumstick.sourceforge.net/"
+url="https://drumstick.sourceforge.io/"
 license=('GPL2')
-depends=('desktop-file-utils' 'hicolor-icon-theme' 'alsa-lib' 'qt5-base'
-'qt5-svg')
-makedepends=('cmake' 'doxygen' 'docbook-xsl' 'libpulse' 'fluidsynth')
-optdepends=('fluidsynth: for fluidsynth integration'
-            'libpulse: for PulseAudio integration')
-provides=('libdrumstick-alsa.so' 'libdrumstick-file.so' 'libdrumstick-rt.so')
+depends=('gcc-libs' 'glibc' 'hicolor-icon-theme' 'qt5-base')
+makedepends=('alsa-lib' 'cmake' 'doxygen' 'docbook-xsl' 'fluidsynth' 'graphviz'
+'libpulse' 'qt5-tools')
+provides=('libdrumstick-alsa.so' 'libdrumstick-file.so' 'libdrumstick-rt.so'
+'libdrumstick-widgets.so')
 source=("https://downloads.sourceforge.net/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.bz2")
-sha512sums=('8831578a6422cbf6570fd0ff36836f808d452cd7cc338de82cc852d804c5ef404d97dfd73760b13f16fe33007b35a5fc4591f2c4d719a4cf2b6a34fa6ca81a8b')
+sha512sums=('09adaf7901ba57419222d3560e9212633ba5bfad37ebd113c8c56ddc83d5e55a0beccaa7c45b7eef3858f624cced15c516245ee970786813a1defcb20b247636')
+b2sums=('c1a3f1290b8afd973f8ef2ab35515c41cb2cf5b618d67da652ab33c9015778870d8b1f1ca724b2c0d2f1dc5d743ba7b64b388b58e6f8d434a20da7ef00b33845')
 
-prepare() {
-  cd "${pkgname}-${pkgver}"
-  # removing specific check for fluidsynth == 1.1.11, as fluidsynth > 2.0.0
-  # compiles just fine
-  sed -E 's|(pkg_check_modules\(FLUIDSYNTH ).+|\1fluidsynth\)|g' \
-      -i library/rt-backends/CMakeLists.txt
-}
-
 build() {
   cd "${pkgname}-${pkgver}"
   cmake -DCMAKE_INSTALL_PREFIX=/usr \
-        -DCMAKE_BUILD_TYPE=Release
-  make
+        -DCMAKE_BUILD_TYPE='None' \
+        -Wno-dev \
+        -B build \
+        -S .
+  make VERBOSE=1 -C build
 }
 
+# # tests fail and seem to provide no further logs:
+# # https://sourceforge.net/p/drumstick/bugs/24/
+# check() {
+#   cd "${pkgname}-${pkgver}"
+#   make test -C build
+# }
+
 package() {
+  depends+=('libasound.so' 'libfluidsynth.so' 'libpulse.so' 'libpulse-simple.so')
   cd "${pkgname}-${pkgver}"
-  make DESTDIR="${pkgdir}/" install
+  make DESTDIR="${pkgdir}/" install -C build
   install -t "${pkgdir}/usr/share/doc/${pkgname}/" \
     -vDm 644 {AUTHORS,ChangeLog,NEWS,README,TODO}
 }