[arch-commits] Commit in tcpdump/trunk (PKGBUILD)

[David Runge]

    Date: Friday, January 8, 2021 @ 19:28:26
  Author: dvzrv
Revision: 405745

upgpkg: tcpdump 4.99.0-1: Upgrade to 4.99.0.

Add all direct dependencies in depends.
Add all available sodeps in package() and the respective packages in makedepends.
Switch to cmake as build system to avoid removing versioned binary in package().
Update maintainer info.

Modified:
  tcpdump/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++--------------------
 1 file changed, 24 insertions(+), 20 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2021-01-08 18:56:40 UTC (rev 405744)
+++ PKGBUILD	2021-01-08 19:28:26 UTC (rev 405745)
@@ -1,38 +1,42 @@
-# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Gaetan Bisson <bisson at archlinux.org>
 # Contributor: Giovanni Scafora <giovanni at archlinux.org>
 # Contributor: dorphell <dorphell at archlinux.org>
 
 pkgname=tcpdump
-pkgver=4.9.3
-pkgrel=2
+pkgver=4.99.0
+pkgrel=1
 pkgdesc='Powerful command-line packet analyzer'
-url='https://www.tcpdump.org/'
+url="https://www.tcpdump.org/"
 arch=('x86_64')
 license=('BSD')
-depends=('libpcap' 'libcap-ng' 'openssl')
+depends=('glibc' 'openssl')
+makedepends=('cmake' 'libpcap' 'libcap-ng')
 source=("https://www.tcpdump.org/release/${pkgname}-${pkgver}.tar.gz"{,.sig})
-#source=("https://sources.archlinux.org/other/packages/tcpdump/${pkgname}-${pkgver}.tar.gz"{,.sig})
-validpgpkeys=('1F166A5742ABB9E0249A8D30E089DEF1D9C15D0D')
-sha256sums=('2cd47cb3d460b6ff75f4a9940f594317ad456cfbf2bd2c8e5151e16559db6410'
+sha512sums=('03a434ec41c0026f237bc1e7a928b7ce67dbc342a8d982caded93d987bd356faf706a9d884231bd94f5e2a8580499fe95a28728e37a6672e371a1501ec5d6f79'
             'SKIP')
+b2sums=('389939ea501edf66b7bb809c835feffebf15f30fbba559ce40963733a79ca271982336884acd7ff3d078decb1aaea0616d98091199918b520ef3d1fe0f194431'
+        'SKIP')
+validpgpkeys=('1F166A5742ABB9E0249A8D30E089DEF1D9C15D0D') # The Tcpdump Group (Package signing key) <release at tcpdump.org>
 
 build() {
-	cd "${srcdir}/${pkgname}-${pkgver}"
-	./configure \
-		--prefix=/usr \
-		--sbindir=/usr/bin \
-
-	make
+  cd "${pkgname}-${pkgver}"
+  cmake -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE='None' \
+        -Wno-dev \
+        -B build \
+        -S .
+  make VERBOSE=1 -C build
 }
 
 check() {
-	cd "${srcdir}/${pkgname}-${pkgver}"
-	make check
+  cd "${pkgname}-${pkgver}"
+  make VERBOSE=1 check -C build
 }
 
 package() {
-	cd "${srcdir}/${pkgname}-${pkgver}"
-	make DESTDIR="${pkgdir}" install
-	install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-	rm -f "${pkgdir}"/usr/bin/tcpdump.${pkgver}
+  depends+=('libpcap.so' 'libcap-ng.so')
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" install -C build
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
 }