[arch-commits] Commit in haskell-postgresql-binary/repos (2 files)

[Felix Yan]

    Date: Tuesday, January 12, 2021 @ 16:10:28
  Author: felixonmars
Revision: 820026

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-postgresql-binary/repos/community-staging-x86_64/
  haskell-postgresql-binary/repos/community-staging-x86_64/PKGBUILD
    (from rev 820025, haskell-postgresql-binary/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: haskell-postgresql-binary/repos/community-staging-x86_64/PKGBUILD (from rev 820025, haskell-postgresql-binary/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-12 16:10:28 UTC (rev 820026)
@@ -0,0 +1,59 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=postgresql-binary
+pkgname=haskell-postgresql-binary
+pkgver=0.12.3.3
+pkgrel=23
+pkgdesc="Encoders and decoders for the PostgreSQL's binary format"
+url="https://github.com/nikita-volkov/postgresql-binary"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-base-prelude' 'haskell-binary-parser'
+         'haskell-bytestring-strict-builder' 'haskell-loch-th' 'haskell-network-ip'
+         'haskell-placeholders' 'haskell-scientific' 'haskell-unordered-containers'
+         'haskell-uuid' 'haskell-vector')
+makedepends=('ghc' 'haskell-postgresql-libpq' 'haskell-tasty' 'haskell-tasty-quickcheck'
+             'haskell-tasty-hunit' 'haskell-quickcheck' 'haskell-quickcheck-instances'
+             'haskell-json-ast' 'haskell-conversion' 'haskell-conversion-bytestring'
+             'haskell-conversion-text' 'haskell-rerebase' 'pifpaf' 'postgresql')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('1d7fb657069a68e151c72c21d2aacf500756fa86fcb5ce546f63692a88bc2066f78feb563e0239afc370ace02dd5b47a19291bbe751d7642c34a879e5bf9bcfd')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    # Do not use default postgres port
+    sed -i 's/5432/9824/' tasty/Main/DB.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+
+    eval $(pifpaf run postgresql --host 127.0.0.1)
+    createuser -s postgres
+    runhaskell Setup test
+    pifpaf_stop
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}