[arch-commits] Commit in (3 files)

[Maxime Gauduin]

    Date: Wednesday, January 13, 2021 @ 13:38:48
  Author: alucryd
Revision: 820459

add python-mediafile for beets

Added:
  python-mediafile/
  python-mediafile/trunk/
  python-mediafile/trunk/PKGBUILD

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Added: python-mediafile/trunk/PKGBUILD
===================================================================
--- python-mediafile/trunk/PKGBUILD	                        (rev 0)
+++ python-mediafile/trunk/PKGBUILD	2021-01-13 13:38:48 UTC (rev 820459)
@@ -0,0 +1,46 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Frederik “Freso” S. Olesen <freso.dk at gmail.com>
+
+pkgname=python-mediafile
+pkgver=0.6.0.r12.d7bea5e
+pkgrel=1
+pkgdesc='Elegant audio file tagging'
+arch=(any)
+url=https://github.com/beetbox/mediafile
+license=(MIT)
+depends=(
+  python-mutagen
+  python-six
+)
+makedepends=(
+  git
+  python-flit
+  python-pip
+  python-poetry
+)
+checkdepends=(python-nose)
+_commit=d7bea5efbe00c54fbe9ca169a3ffd6c827302e7d
+source=(git+https://github.com/beetbox/mediafile.git#commit=${_commit})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd mediafile
+  git describe --tags | sed 's/^v//; s/-/.r/; s/-g/./'
+}
+
+build() {
+  cd mediafile
+  flit build --format wheel
+}
+
+check() {
+  cd mediafile
+  python -m nose
+}
+
+package() {
+  PIP_CONFIG_FILE=/dev/null pip install --isolated --root="${pkgdir}" --ignore-installed --no-deps mediafile/dist/*.whl
+  install -Dm 644 mediafile/LICENSE -t "${pkgdir}"/usr/share/licenses/python-mediafile
+}
+
+# vim: ts=2 sw=2 et: