[arch-commits] Commit in mpv/repos (2 files)

[Christian Hesse]

    Date: Thursday, January 14, 2021 @ 07:06:39
  Author: eworm
Revision: 820768

archrelease: copy trunk to community-staging-x86_64

Added:
  mpv/repos/community-staging-x86_64/
  mpv/repos/community-staging-x86_64/PKGBUILD
    (from rev 820767, mpv/trunk/PKGBUILD)

----------+
 PKGBUILD |   68 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)

Copied: mpv/repos/community-staging-x86_64/PKGBUILD (from rev 820767, mpv/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-14 07:06:39 UTC (rev 820768)
@@ -0,0 +1,68 @@
+# Maintainer: Christian Hesse <mail at eworm.de>
+# Contributor: Bartłomiej Piotrowski <bpiotrowski at archlinux.org>
+# Contributor: Eivind Uggedal <eivind at uggedal.com>
+
+pkgname=mpv
+epoch=1
+_tag='d5ae9f70ea1f21c1d3794df5345a6a9366188660' # git rev-parse v${pkgver}
+pkgver=0.33.0
+pkgrel=4
+pkgdesc='a free, open source, and cross-platform media player'
+arch=('x86_64')
+# We link against libraries that are licensed GPLv3 explicitly, so our
+# package is GPLv3 only as well. (Is this still correct?)
+license=('GPL3')
+url='https://mpv.io/'
+depends=('alsa-lib' 'libasound.so' 'desktop-file-utils' 'ffmpeg' 'libavcodec.so' 'libavdevice.so'
+         'libavfilter.so' 'libavformat.so' 'libavutil.so' 'libswresample.so' 'libswscale.so'
+         'glibc' 'hicolor-icon-theme' 'jack' 'libjack.so' 'lcms2' 'liblcms2.so' 'libarchive'
+         'libarchive.so' 'libass' 'libass.so' 'libbluray' 'libbluray.so' 'libcaca' 'libcdio'
+         'libcdio-paranoia' 'libdrm' 'libdvdnav' 'libdvdread' 'libegl' 'libgl' 'libglvnd'
+         'libjpeg' 'libjpeg.so' 'libplacebo' 'libplacebo.so' 'libpulse' 'libpulse.so'
+         'libva' 'libva.so' 'libva-drm.so' 'libva-wayland.so' 'libva-x11.so' 'libvdpau' 'libx11'
+         'libxext' 'libxinerama' 'libxkbcommon' 'libxkbcommon.so' 'libxrandr' 'libxss'
+         'libxv' 'lua52' 'mesa' 'mujs' 'rubberband' 'librubberband.so' 'shaderc'
+         'libshaderc_shared.so' 'uchardet' 'vulkan-icd-loader' 'wayland' 'xdg-utils'
+         'zlib')
+makedepends=('git' 'python-docutils' 'ladspa' 'wayland-protocols'
+             'ffnvcodec-headers' 'vulkan-headers' 'waf')
+optdepends=('youtube-dl: for video-sharing websites playback')
+provides=('libmpv.so')
+options=('!emptydirs')
+validpgpkeys=('145077D82501AA20152CACCE8D769208D5E31419') # sfan5 <sfan5 at live.de>
+source=("git+https://github.com/mpv-player/mpv.git#tag=${_tag}?signed")
+sha256sums=('SKIP')
+
+prepare() {
+  cd ${pkgname}
+
+  # vo_gpu: placebo: update for upstream API changes
+  git cherry-pick -n 7c4465cefb27d4e0d07535d368febdf77b579566
+}
+
+build() {
+  cd ${pkgname}
+
+  waf configure --prefix=/usr \
+    --confdir=/etc/mpv \
+    --enable-cdda \
+    --enable-dvb \
+    --enable-dvdnav \
+    --enable-libarchive \
+    --enable-libmpv-shared \
+    --disable-build-date
+
+  waf build
+}
+
+package() {
+  cd ${pkgname}
+
+  waf install --destdir="$pkgdir"
+
+  install -m0644 DOCS/{encoding.rst,tech-overview.txt} \
+    "$pkgdir"/usr/share/doc/mpv
+
+  install -m0644 TOOLS/lua/* \
+    -D -t "$pkgdir"/usr/share/mpv/scripts
+}