[arch-commits] Commit in ctags/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Levente Polyak]

    Date: Friday, January 15, 2021 @ 00:10:22
  Author: anthraxx
Revision: 406268

archrelease: copy trunk to testing-x86_64

Added:
  ctags/repos/testing-x86_64/
  ctags/repos/testing-x86_64/PKGBUILD
    (from rev 406267, ctags/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: ctags/repos/testing-x86_64/PKGBUILD (from rev 406267, ctags/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-01-15 00:10:22 UTC (rev 406268)
@@ -0,0 +1,47 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Giovanni Scafora <giovanni at archlinux.org>
+# Contributor: John Proctor <jproctor at prium.net>
+
+pkgname=ctags
+_commit=08b1c490cc4a20c3983314ae112c48edba0d51ed  # p5.9.20210110.0
+pkgver=r20210106+g08b1c490
+pkgrel=1
+epoch=1
+pkgdesc='Generates an index file of language objects found in source files'
+url='https://ctags.io/'
+arch=('x86_64')
+license=('GPL')
+depends=('glibc' 'libxml2' 'jansson' 'libyaml' 'libseccomp' 'libseccomp.so')
+makedepends=('git' 'python-docutils')
+provides=('universal-ctags')
+source=("git+https://github.com/universal-ctags/ctags.git#commit=$_commit")
+sha512sums=('SKIP')
+
+pkgver() {
+  git -C ctags show --pretty='r%cd+g%h' --date='format:%Y%m%d' --no-patch
+}
+
+prepare() {
+  cd ctags
+  autoreconf -fiv
+}
+
+build() {
+  cd ctags
+  ./configure \
+    --prefix=/usr \
+    --sysconfdir=/etc \
+    --localstatedir=/var \
+    --libexecdir=/usr/lib
+  make
+}
+
+check() {
+  make -C ctags check
+}
+
+package() {
+  make -C ctags DESTDIR="${pkgdir}" install
+}
+
+# vim:set sw=2 et: