[arch-commits] Commit in php-imagick/repos (3 files)

[Pierre Schmitz]

    Date: Monday, January 18, 2021 @ 17:45:07
  Author: pierre
Revision: 823585

db-move: moved php-imagick from [community-staging] to [community-testing] (x86_64)

Added:
  php-imagick/repos/community-testing-x86_64/
  php-imagick/repos/community-testing-x86_64/PKGBUILD
    (from rev 823584, php-imagick/repos/community-staging-x86_64/PKGBUILD)
Deleted:
  php-imagick/repos/community-staging-x86_64/

----------+
 PKGBUILD |   92 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 92 insertions(+)

Copied: php-imagick/repos/community-testing-x86_64/PKGBUILD (from rev 823584, php-imagick/repos/community-staging-x86_64/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-01-18 17:45:07 UTC (rev 823585)
@@ -0,0 +1,92 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=imagick
+pkgbase=php-imagick
+pkgname=('php-imagick' 'php7-imagick')
+_commit="448c1cd0d58ba2838b9b6dff71c9b7e70a401b90"
+pkgver=3.4.4.r66.g448c1cd
+pkgrel=1
+pkgdesc="PHP extension to create and modify images using the ImageMagick library"
+arch=('x86_64')
+url="https://github.com/imagick/imagick"
+license=('PHP')
+depends=('imagemagick' 'ttf-font')
+makedepends=('git' 'php' 'php7')
+checkdepends=('librsvg' 'ttf-dejavu')
+source=("${pkgbase}::git+https://github.com/${_name}/${_name}#commit=${_commit}")
+sha512sums=('SKIP')
+b2sums=('SKIP')
+
+pkgver() {
+  cd "$pkgbase"
+  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  # setting package version: https://bugs.archlinux.org/task/64185
+  sed -e "s/@PACKAGE_VERSION@/${pkgver}/" \
+      -i "${pkgbase}/php_imagick.h" "${pkgbase}/package.xml"
+  echo ";extension=${_name}" > "${pkgbase}/${_name}.ini"
+
+  cp -av "${pkgbase}" "${pkgname[1]}"
+  (
+    cd "$pkgname"
+    phpize
+  )
+  (
+    cd "${pkgname[1]}"
+    phpize7
+  )
+}
+
+build() {
+  (
+    cd "$pkgname"
+    ./configure --prefix=/usr
+    make
+  )
+  (
+    cd "${pkgname[1]}"
+    ./configure --prefix=/usr
+    make
+  )
+}
+
+check() {
+  (
+    cd "$pkgname"
+    export NO_INTERACTION="true"
+    make -k test
+  )
+  (
+    cd "${pkgname[1]}"
+    export NO_INTERACTION="true"
+    make -k test
+  )
+}
+
+package_php-imagick() {
+  depends+=('php')
+  backup=("etc/php/conf.d/${_name}.ini")
+
+  cd "$pkgname"
+  make INSTALL_ROOT="$pkgdir/" install
+  install -vDm 644 "${_name}.ini" -t "${pkgdir}/etc/php/conf.d/"
+  install -vDm 644 {ChangeLog,CREDITS,README.md} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/"
+  install -vDm 644 examples/*.php \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
+}
+
+package_php7-imagick() {
+  depends+=('php7')
+  backup=("etc/php7/conf.d/${_name}.ini")
+
+  cd "$pkgname"
+  make INSTALL_ROOT="$pkgdir/" install
+  install -vDm 644 "${_name}.ini" -t "${pkgdir}/etc/php7/conf.d/"
+  install -vDm 644 {ChangeLog,CREDITS,README.md} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/"
+  install -vDm 644 examples/*.php \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
+}