[arch-commits] Commit in php-memcached/repos (3 files)
Pierre Schmitz
pierre at archlinux.org
Mon Jan 18 17:45:09 UTC 2021
Date: Monday, January 18, 2021 @ 17:45:08
Author: pierre
Revision: 823587
db-move: moved php-memcached from [community-staging] to [community-testing] (x86_64)
Added:
php-memcached/repos/community-testing-x86_64/
php-memcached/repos/community-testing-x86_64/PKGBUILD
(from rev 823586, php-memcached/repos/community-staging-x86_64/PKGBUILD)
Deleted:
php-memcached/repos/community-staging-x86_64/
----------+
PKGBUILD | 60 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 60 insertions(+)
Copied: php-memcached/repos/community-testing-x86_64/PKGBUILD (from rev 823586, php-memcached/repos/community-staging-x86_64/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD (rev 0)
+++ community-testing-x86_64/PKGBUILD 2021-01-18 17:45:08 UTC (rev 823587)
@@ -0,0 +1,60 @@
+# Maintainer: Evangelos Foutras <evangelos at foutrelis.com>
+
+pkgname=('php-memcached' 'php7-memcached')
+pkgver=3.1.5.r16.gbfb0a66
+_commit=bfb0a66809d43080219ab5381235f848c91eff7e
+pkgrel=1
+pkgdesc="PHP extension for interfacing with memcached via libmemcached library"
+arch=('x86_64')
+url="https://github.com/php-memcached-dev/php-memcached"
+license=('PHP')
+depends=('libmemcached')
+makedepends=('php' 'php7' 'git')
+source=("git+https://github.com/php-memcached-dev/php-memcached.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+ cd $pkgbase
+ git describe --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+ cp -a $pkgbase{,-php7}
+}
+
+build() {
+ cd $pkgbase
+ phpize
+ ./configure --prefix=/usr
+ make
+
+ cd ../$pkgbase-php7
+ phpize7
+ ./configure --prefix=/usr
+ make
+}
+
+package_php-memcached() {
+ depends+=('php')
+ backup=('etc/php/conf.d/memcached.ini')
+
+ cd $pkgbase
+
+ make INSTALL_ROOT="$pkgdir" install
+ install -d "$pkgdir/etc/php/conf.d"
+ echo ';extension=memcached.so' >"$pkgdir/etc/php/conf.d/memcached.ini"
+}
+
+package_php7-memcached() {
+ pkgdesc=${pkgdesc/PHP/PHP 7}
+ depends+=('php7')
+ backup=('etc/php7/conf.d/memcached.ini')
+
+ cd $pkgbase-php7
+
+ make INSTALL_ROOT="$pkgdir" install
+ install -d "$pkgdir/etc/php7/conf.d"
+ echo ';extension=memcached.so' >"$pkgdir/etc/php7/conf.d/memcached.ini"
+}
+
+# vim:set ts=2 sw=2 et:
More information about the arch-commits
mailing list