[arch-commits] Commit in radare2/repos (2 files)

[Levente Polyak]

    Date: Thursday, January 21, 2021 @ 00:28:17
  Author: anthraxx
Revision: 824040

archrelease: copy trunk to community-staging-x86_64

Added:
  radare2/repos/community-staging-x86_64/
  radare2/repos/community-staging-x86_64/PKGBUILD
    (from rev 824039, radare2/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: radare2/repos/community-staging-x86_64/PKGBUILD (from rev 824039, radare2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-21 00:28:17 UTC (rev 824040)
@@ -0,0 +1,45 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Guillermo Ramos <0xwille at gmail dot com>
+
+pkgname=radare2
+pkgver=5.0.0
+pkgrel=1
+pkgdesc='Open-source tools to disasm, debug, analyze and manipulate binary files'
+url='https://radare.org'
+arch=('x86_64')
+license=('GPL3' 'LGPL3')
+depends=('sh' 'capstone' 'libcapstone.so' 'openssl' 'libzip' 'zlib'
+         'lz4' 'xxhash' 'libxxhash.so' 'file' 'libuv' 'tree-sitter'
+         'libtree-sitter.so')
+makedepends=('meson')
+optdepends=('r2ghidra: ghidra decompiler plugin')
+options=('!emptydirs')
+source=(https://github.com/radare/radare2/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('059bc341bc34c5f39ef7493af9e2d3b7e52667a2d16f12ef19c9c6ba83c911fd02e07cd527599caea503d5e81a5fedbd8ff343db4d41257e0f48ace9dd52f3ba')
+b2sums=('be785b693e9de7264f21b857291286849e054e807d87b4c56a6177a132f9fa141c25661f9d28ea10b61fd298161693794f2ee70279cfd076a2b1a98c563dd2a9')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  touch libr/config.mk
+  arch-meson build \
+    -D use_sys_capstone=true \
+    -D use_sys_magic=true \
+    -D use_sys_zip=true \
+    -D use_sys_zlib=true \
+    -D use_sys_lz4=true \
+    -D use_sys_xxhash=true \
+    -D use_sys_openssl=true \
+    -D use_libuv=true \
+    -D use_webui=true \
+    -D use_sys_tree_sitter=true
+  ninja -C build
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  DESTDIR="${pkgdir}" ninja -C build install
+  cp -r doc/* "${pkgdir}/usr/share/doc/radare2"
+  ln -s /usr/share/man/man1/radare2.1.gz "${pkgdir}/usr/share/man/man1/r2.1.gz"
+}
+
+# vim: ts=2 sw=2 et: