[arch-commits] Commit in (4 files)
Levente Polyak
anthraxx at archlinux.org
Thu Jan 21 00:37:26 UTC 2021
Date: Thursday, January 21, 2021 @ 00:37:25
Author: anthraxx
Revision: 824041
addpkg: r2ghidra 5.0.0.r16.gb5b89227-1: backport patches required to build against radare2 5.0.0
Added:
r2ghidra/
r2ghidra/repos/
r2ghidra/trunk/
r2ghidra/trunk/PKGBUILD
----------+
PKGBUILD | 61 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 61 insertions(+)
Added: r2ghidra/trunk/PKGBUILD
===================================================================
--- r2ghidra/trunk/PKGBUILD (rev 0)
+++ r2ghidra/trunk/PKGBUILD 2021-01-21 00:37:25 UTC (rev 824041)
@@ -0,0 +1,61 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+
+pkgname=r2ghidra
+_gitcommit=b5b8922763f515f4048f25818fe7a67186ce92f6
+_gitcutter=d7543100963c382c01fa6adf6c7c81c27dbb6722
+pkgver=5.0.0.r16.gb5b89227
+pkgrel=1
+pkgdesc='Deep ghidra decompiler integration for radare2 and r2cutter'
+url='https://github.com/radareorg/r2ghidra'
+arch=('x86_64')
+license=('LGPL3')
+depends=('radare2' 'glibc')
+makedepends=('git' 'cmake' 'qt5-base')
+provides=('r2cutter-r2ghidra'
+ 'radare2-r2ghidra')
+replaces=('r2ghidra-dec')
+source=("git+https://github.com/radareorg/r2ghidra#commit=${_gitcommit}"
+ "git+https://github.com/radareorg/r2cutter#commit=${_gitcutter}"
+ radare-ghidra::git+https://github.com/radareorg/ghidra.git
+ git+https://github.com/zeux/pugixml.git)
+sha512sums=('SKIP'
+ 'SKIP'
+ 'SKIP'
+ 'SKIP')
+
+pkgver() {
+ cd ${pkgname}
+ git describe --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+ cd ${pkgname}
+ git submodule init
+ git config submodule."third-party/pugixml".url "${srcdir}/pugixml"
+ git config submodule."ghidra/ghidra".url "${srcdir}/radare-ghidra"
+ git submodule update --recursive
+}
+
+build() {
+ cd ${pkgname}
+ cmake \
+ -B build \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_BUILD_TYPE=None \
+ -DBUILD_CUTTER_PLUGIN=ON \
+ -DBUILD_SLASPECS=ON \
+ -DCUTTER_SOURCE_DIR="${srcdir}/r2cutter"
+ make -C build VERBOSE=1
+}
+
+package() {
+ cd ${pkgname}
+ make -C build -j1 DESTDIR="${pkgdir}" install
+ # move shared library into R2_LIBR_PLUGINS
+ r2version=$(r2 -version|grep radare2|sed -E 's/radare2 ([0-9\.]+) .*/\1/')
+ install -d "${pkgdir}/usr/lib/radare2"
+ mv "${pkgdir}/usr/lib/radare2/last" "${pkgdir}/usr/lib/radare2/${r2version}"
+ ln -s /usr/lib/radare2/${r2version} "${pkgdir}/usr/lib/radare2/last"
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list