[arch-commits] Commit in tinycdb/trunk (PKGBUILD)

[David Runge]

    Date: Friday, January 22, 2021 @ 13:33:17
  Author: dvzrv
Revision: 406611

upgpkg: tinycdb 0.78-5: Rebuild to add sodeps.

Add libcdb.so to provides.
Switch to TLS for upstream url and sources.
Use the staticlibs option to remove libcdb.a instead of relying on modifying the Makefile.
Install docs.
Update maintainer info.

Modified:
  tinycdb/trunk/PKGBUILD

----------+
 PKGBUILD |   39 ++++++++++++++++++++++-----------------
 1 file changed, 22 insertions(+), 17 deletions(-)

Modified: PKGBUILD
===================================================================
--- PKGBUILD	2021-01-22 08:23:27 UTC (rev 406610)
+++ PKGBUILD	2021-01-22 13:33:17 UTC (rev 406611)
@@ -1,29 +1,34 @@
-# Maintainer: Gaetan Bisson <bisson at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Gaetan Bisson <bisson at archlinux.org>
 # Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
 
 pkgname=tinycdb
 pkgver=0.78
-pkgrel=4
+pkgrel=5
 pkgdesc='Very fast and simple package for creating and reading constant data bases'
-url='http://www.corpit.ru/mjt/tinycdb.html'
+arch=('x86_64')
+url="https://www.corpit.ru/mjt/tinycdb.html"
 license=('custom')
-arch=('x86_64')
-source=("http://www.corpit.ru/mjt/tinycdb/${pkgname}-${pkgver}.tar.gz")
-sha256sums=('50678f432d8ada8d69f728ec11c3140e151813a7847cf30a62d86f3a720ed63c')
+depends=('glibc')
+provides=('libcdb.so')
+# we don't want libcdb.a and would need to modify the Makefile otherwise
+options=(!staticlibs)
+source=("https://www.corpit.ru/mjt/tinycdb/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('8930086b8e7fddcd4dbd3354c5f5ee05171df68fde1cc222b6c402430042b6e761efbad7e5fa8de18e1d36390f1526cc3e605c5086fe1c363ba1df6c03201553')
+b2sums=('41f4256840645acd28296c5473087c7cf4c026f068310375b3c305430c030b1c946f53fd3e09967d77b592ba84e7e56518fdb18e54d1e0f5e7dd552a1664a0ec')
 
-prepare() {
-	cd "${srcdir}/${pkgname}-${pkgver}"
-	sed -e 's/all: static/all: shared/' -e '/libcdb.a/d' -i Makefile
-}
-
 build() {
-	cd "${srcdir}/${pkgname}-${pkgver}"
-	make CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
+  cd "${pkgname}-${pkgver}"
+  make CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}" all shared
 }
 
 package() {
-	cd "${srcdir}/${pkgname}-${pkgver}"
-	make DESTDIR="${pkgdir}" prefix=/usr mandir=/usr/share/man \
-		INSTALLPROG=cdb-shared install-{all,sharedlib}
-	install -Dm644 debian/copyright "${pkgdir}"/usr/share/licenses/tinycdb/copyright
+  cd "${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" \
+       prefix=/usr \
+       mandir=/usr/share/man \
+       INSTALLPROG=cdb-shared \
+       install-{all,sharedlib}
+  install -vDm 644 debian/copyright -t "${pkgdir}/usr/share/licenses/${pkgname}/"
+  install -vDm 644 {NEWS,ChangeLog} -t "${pkgdir}/usr/share/doc/${pkgname}/"
 }