[arch-commits] Commit in haskell-skylighting-core/repos (2 files)

[Felix Yan]

    Date: Sunday, January 24, 2021 @ 20:02:35
  Author: felixonmars
Revision: 829061

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-skylighting-core/repos/community-staging-x86_64/
  haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 829060, haskell-skylighting-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)

Copied: haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD (from rev 829060, haskell-skylighting-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-24 20:02:35 UTC (rev 829061)
@@ -0,0 +1,42 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=skylighting-core
+pkgname=haskell-skylighting-core
+pkgver=0.10.2
+pkgrel=5
+pkgdesc="Syntax highlighting library"
+url="https://github.com/jgm/skylighting"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-attoparsec'
+         'haskell-base64-bytestring' 'haskell-blaze-html' 'haskell-case-insensitive'
+         'haskell-colour' 'haskell-hxt' 'haskell-safe' 'haskell-utf8-string')
+makedepends=('ghc' 'haskell-diff' 'haskell-hunit' 'haskell-pretty-show' 'haskell-quickcheck'
+             'haskell-random' 'haskell-tasty' 'haskell-tasty-golden' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('c3d20694b29dee660cbba681dec4b7610b1b5be8e5b359931935b0e2a466f41a494847231557c6c5906d5b31487360516af0e00c46689cbc03c9de58e3430698')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fexecutable
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}