[arch-commits] Commit in (5 files)

[Anatol Pomozov]

    Date: Monday, January 25, 2021 @ 19:05:23
  Author: anatolik
Revision: 829780

Add aws/s2n to [community]

Added:
  s2n/
  s2n/repos/
  s2n/trunk/
  s2n/trunk/PKGBUILD
  s2n/trunk/missing_symbol_workaround.patch

---------------------------------+
 PKGBUILD                        |   40 ++++++++++++++++++++++++++++++++++++++
 missing_symbol_workaround.patch |   13 ++++++++++++
 2 files changed, 53 insertions(+)

Added: s2n/trunk/PKGBUILD
===================================================================
--- s2n/trunk/PKGBUILD	                        (rev 0)
+++ s2n/trunk/PKGBUILD	2021-01-25 19:05:23 UTC (rev 829780)
@@ -0,0 +1,40 @@
+# Maintainer: Anatol Pomozov
+
+pkgname=s2n
+pkgver=0.10.25
+pkgrel=1
+pkgdesc='A C99 implementation of the TLS/SSL protocols that is designed to be simple, small, fast, and with security as a priority'
+arch=(x86_64)
+url='https://github.com/awslabs/s2n'
+license=(Apache)
+depends=(openssl)
+makedepends=(cmake)
+source=(s2n-$pkgver.zip::https://github.com/awslabs/s2n/archive/v$pkgver.zip
+        missing_symbol_workaround.patch)
+sha256sums=('2d6e229e9fb1e4fcc16aee24155089772176db4d3a32e6731634b7e4c27728ee'
+            'd86e81598a79de7353262eeffc490c1e266dc8a92f7057166d447cd36d04eb35')
+
+prepare() {
+  cd s2n-$pkgver
+
+  patch -p1 < ../missing_symbol_workaround.patch # https://github.com/awslabs/s2n/issues/2401
+}
+
+build() {
+  cd s2n-$pkgver
+
+  cmake -DCMAKE_BUILD_TYPE=Release -DCMAKE_INSTALL_PREFIX=/usr -DBUILD_SHARED_LIBS=ON -S . -B build
+  cmake --build build
+}
+
+check() {
+  cd s2n-$pkgver
+  cmake --build build --target test
+}
+
+package() {
+  cd s2n-$pkgver
+
+  cmake --build build --target install -- DESTDIR="$pkgdir/"
+  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+}

Added: s2n/trunk/missing_symbol_workaround.patch
===================================================================
--- s2n/trunk/missing_symbol_workaround.patch	                        (rev 0)
+++ s2n/trunk/missing_symbol_workaround.patch	2021-01-25 19:05:23 UTC (rev 829780)
@@ -0,0 +1,13 @@
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index a93d51f5..8d2806ad 100755
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -177,7 +177,7 @@ set(CMAKE_C_FLAGS_DEBUGOPT "")
+ 
+ target_compile_options(${PROJECT_NAME} PRIVATE -pedantic -std=gnu99 -Wall -Werror -Wimplicit -Wunused -Wcomment -Wchar-subscripts
+         -Wuninitialized -Wshadow -Wcast-qual -Wcast-align -Wwrite-strings -Wno-deprecated-declarations -Wno-unknown-pragmas -Wformat-security
+-        -Wno-missing-braces -fvisibility=hidden -DS2N_EXPORTS)
++        -Wno-missing-braces -DS2N_EXPORTS)
+ 
+ if(S2N_NO_PQ)
+     target_compile_options(${PROJECT_NAME} PUBLIC -DS2N_NO_PQ)