[arch-commits] Commit in haskell-http-api-data/repos (2 files)

[Felix Yan]

    Date: Wednesday, January 27, 2021 @ 06:31:36
  Author: felixonmars
Revision: 831659

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-http-api-data/repos/community-staging-x86_64/
  haskell-http-api-data/repos/community-staging-x86_64/PKGBUILD
    (from rev 831658, haskell-http-api-data/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-http-api-data/repos/community-staging-x86_64/PKGBUILD (from rev 831658, haskell-http-api-data/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-27 06:31:36 UTC (rev 831659)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=http-api-data
+pkgname=haskell-http-api-data
+pkgver=0.4.3
+pkgrel=7
+pkgdesc="Converting to/from HTTP API data like URL pieces, headers and query parameters."
+url="https://github.com/fizruk/http-api-data"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-attoparsec-iso8601' 'haskell-base-compat'
+         'haskell-cookie' 'haskell-hashable' 'haskell-http-types' 'haskell-tagged'
+         'haskell-time-compat' 'haskell-unordered-containers' 'haskell-uuid-types')
+makedepends=('ghc' 'haskell-hspec' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('625367d8f524eff07c69620df17c87a4365c01b9bc8bdd6bab5b8abe1b47cc429a050d63f48e50cb08fcac55aef95dfea532a5d52c87b6fa2d3e58b06aa8f4b0')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-use-text-show
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}