[arch-commits] Commit in step-ca/trunk (PKGBUILD)

[Morten Linderud]

    Date: Thursday, January 28, 2021 @ 23:36:02
  Author: foxboron
Revision: 833606

upgpkg: step-ca 0.15.6-1

Added:
  step-ca/trunk/PKGBUILD

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-01-28 23:36:02 UTC (rev 833606)
@@ -0,0 +1,38 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+
+pkgname=step-ca
+pkgver=0.15.6
+pkgrel=1
+pkgdesc="A private certificate authority (X.509 & SSH) & ACME server for secure automated certificate management, so you can use TLS everywhere & SSO for SSH."
+url="https://github.com/smallstep/certificates"
+arch=(x86_64)
+license=(Apache)
+depends=(glibc pcsclite)
+makedepends=(go)
+source=("$url/releases/download/v${pkgver}/step-certificates_${pkgver}.tar.gz")
+sha512sums=('61450abdc62402d04f0e8344b1477d9236f764f693ee64653c52dee5fe939a71149cb7af06bcafdc9af251f3668cde22fe9da2d87672de28b603d1edb2ca6922')
+
+prepare(){
+  mkdir -p bin
+}
+
+build() {
+  BUILD_DATE="$(date --date="@${SOURCE_DATE_EPOCH:-$(date +%s)}" '+%Y-%m-%d %H:%M UTC')"
+  go build \
+      -trimpath \
+      -buildmode=pie \
+      -mod=readonly \
+      -modcacherw \
+      -ldflags "-linkmode external -extldflags \"${LDFLAGS}\" -X \"main.Version=${pkgver}\" -X \"main.BuildTime=${BUILD_DATE}\"" \
+      -o bin ./cmd/...
+}
+
+check() {
+  go test -v ./...
+}
+
+package() {
+  for bin in step-awskms-init  step-ca  step-cloudkms-init  step-yubikey-init; do
+    install -Dm755 "bin/$bin" "$pkgdir/usr/bin/$bin"
+  done
+}