[arch-commits] Commit in haskell-uri-bytestring/repos (2 files)

[Felix Yan]

    Date: Friday, January 29, 2021 @ 13:58:33
  Author: felixonmars
Revision: 834693

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-uri-bytestring/repos/community-staging-x86_64/
  haskell-uri-bytestring/repos/community-staging-x86_64/PKGBUILD
    (from rev 834692, haskell-uri-bytestring/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-uri-bytestring/repos/community-staging-x86_64/PKGBUILD (from rev 834692, haskell-uri-bytestring/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-29 13:58:33 UTC (rev 834693)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=uri-bytestring
+pkgname=haskell-uri-bytestring
+pkgver=0.3.3.0
+pkgrel=23
+pkgdesc="Haskell URI parsing as ByteStrings"
+url="https://github.com/Soostone/uri-bytestring"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec' 'haskell-blaze-builder' 'haskell-th-lift-instances')
+makedepends=('ghc' 'haskell-hunit' 'haskell-hedgehog' 'haskell-tasty' 'haskell-tasty-hedgehog'
+             'haskell-tasty-hunit' 'haskell-base-compat' 'haskell-safe')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('29be8a04bc95e5d86cb3f1c042e0acfec3970af7d9424c8e3218e143b2b9d783d1e7585597ba588928bd843b4d7f02dbb7f3ad862f39c60e4baa6c262faa9669')
+
+prepare() {
+    sed -e '/, semigroups/d' -i ${_hkgname}-${pkgver}/${_hkgname}.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --disable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-lib-Werror
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    # https://github.com/Soostone/uri-bytestring/issues/50
+    # runhaskell Setup test
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}