[arch-commits] Commit in composer/repos/extra-any (PKGBUILD PKGBUILD)

[Pierre Schmitz]

    Date: Saturday, January 30, 2021 @ 11:05:16
  Author: pierre
Revision: 406924

archrelease: copy trunk to extra-any

Added:
  composer/repos/extra-any/PKGBUILD
    (from rev 406923, composer/trunk/PKGBUILD)
Deleted:
  composer/repos/extra-any/PKGBUILD

----------+
 PKGBUILD |  105 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 51 insertions(+), 54 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-01-30 11:05:13 UTC (rev 406923)
+++ PKGBUILD	2021-01-30 11:05:16 UTC (rev 406924)
@@ -1,54 +0,0 @@
-# Maintainer: Pierre Schmitz <pierre at archlinux.de>
-
-pkgname=composer
-pkgver=2.0.8
-pkgrel=2
-pkgdesc="Dependency Manager for PHP"
-arch=('any')
-license=('MIT')
-url='https://getcomposer.org/'
-depends=('php' 'unzip')
-makedepends=('git')
-checkdepends=('php7' 'php7-intl')
-source=("${pkgname}::git+https://github.com/composer/composer.git#tag=${pkgver}"
-        "${pkgname}-${pkgver}.phar::https://getcomposer.org/download/${pkgver}/composer.phar")
-sha256sums=('SKIP'
-            '2021f0d52b446e0efe3c548cc058ab5671fa38cdbcf814e7911c7e9d71d61538')
-COMPOSER_FLAGS="--ansi --no-interaction --no-progress --prefer-dist"
-
-prepare() {
-	cd "${srcdir}/${pkgname}"
-
-	php "${srcdir}/${pkgname}-${pkgver}.phar" install --no-dev ${COMPOSER_FLAGS}
-}
-
-build() {
-	cd "${srcdir}/${pkgname}"
-
-	php -d phar.readonly=Off bin/compile
-}
-
-check() {
-	cd "${srcdir}/${pkgname}"
-
-	# check if the upstream build and ours differ
-	diff -q ${srcdir}/${pkgname}-${pkgver}.phar composer.phar > /dev/null || msg2 "Upstream composer differs from ours"
-
-	# Install the dev dependencies to run the unit tests
-	bin/composer install ${COMPOSER_FLAGS}
-
-	bin/composer validate
-
-	git config --global user.email composer at example.com
-	git config --global user.name composer
-
-	# use PHP 7 to run tests as this version of PHPUnit is not compatible
-	php7 -d extension=intl vendor/bin/simple-phpunit
-}
-
-package() {
-	cd "${srcdir}/${pkgname}"
-
-	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-	install -Dm755 composer.phar "${pkgdir}/usr/bin/composer"
-}

Copied: composer/repos/extra-any/PKGBUILD (from rev 406923, composer/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-01-30 11:05:16 UTC (rev 406924)
@@ -0,0 +1,51 @@
+# Maintainer: Pierre Schmitz <pierre at archlinux.de>
+
+pkgname=composer
+pkgver=2.0.9
+pkgrel=1
+pkgdesc="Dependency Manager for PHP"
+arch=('any')
+license=('MIT')
+url='https://getcomposer.org/'
+depends=('php' 'unzip')
+makedepends=('git')
+source=("${pkgname}::git+https://github.com/composer/composer.git#tag=${pkgver}"
+	"${pkgname}-${pkgver}.phar::https://getcomposer.org/download/${pkgver}/composer.phar")
+sha256sums=('SKIP'
+	'24faa5bc807e399f32e9a21a33fbb5b0686df9c8850efabe2c047c2ccfb9f9cc')
+
+prepare() {
+	cd "${srcdir}/${pkgname}"
+
+	php "${srcdir}/${pkgname}-${pkgver}.phar" install --no-interaction --no-dev --no-progress --prefer-dist
+}
+
+build() {
+	cd "${srcdir}/${pkgname}"
+
+	php -d phar.readonly=Off bin/compile
+}
+
+check() {
+	cd "${srcdir}"
+
+	mkdir integration-test
+	cd integration-test
+
+	php "${srcdir}/${pkgname}/composer.phar" init \
+		--no-interaction \
+		--type=project \
+		--name='archlinux/test' \
+		--description='Composer Test Project' \
+		--license='GPL-3.0-or-later' \
+		--require='symfony/console:*'
+	php "${srcdir}/${pkgname}/composer.phar" update --no-interaction --no-progress --prefer-dist
+	php "${srcdir}/${pkgname}/composer.phar" validate --no-interaction
+}
+
+package() {
+	cd "${srcdir}/${pkgname}"
+
+	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+	install -Dm755 composer.phar "${pkgdir}/usr/bin/composer"
+}