[arch-commits] Commit in haskell-dbus/repos (2 files)

[Felix Yan]

    Date: Sunday, January 31, 2021 @ 00:38:08
  Author: felixonmars
Revision: 836825

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-dbus/repos/community-staging-x86_64/
  haskell-dbus/repos/community-staging-x86_64/PKGBUILD
    (from rev 836824, haskell-dbus/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-dbus/repos/community-staging-x86_64/PKGBUILD (from rev 836824, haskell-dbus/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-01-31 00:38:08 UTC (rev 836825)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=dbus
+pkgname=haskell-dbus
+pkgver=1.2.18
+pkgrel=4
+pkgdesc="A client library for the D-Bus IPC system"
+url="https://john-millikin.com/software/haskell-dbus/"
+license=("GPL3")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-cereal' 'haskell-conduit' 'haskell-lens'
+         'haskell-network' 'haskell-random' 'haskell-split' 'haskell-th-lift'
+         'haskell-vector' 'haskell-xml-conduit' 'haskell-xml-types')
+makedepends=('ghc' 'haskell-extra' 'haskell-quickcheck' 'haskell-resourcet' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+checkdepends=('dbus')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('cc9220ac9e1f39fb411d2bd0c3ee560519e87763812f9a933c40c4cfaa6377200df9e345c03503071012cabd5998393a51b8ceae6bc2fecf7a1b4650020bfc84')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test || : # https://github.com/rblaze/haskell-dbus/issues/51
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "${pkgdir}/usr/share/doc/${pkgname}/license.txt"
+}