[arch-commits] Commit in haskell-src-meta/repos (2 files)

[Felix Yan]

    Date: Thursday, July 1, 2021 @ 21:34:54
  Author: felixonmars
Revision: 969884

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-src-meta/repos/community-staging-x86_64/
  haskell-src-meta/repos/community-staging-x86_64/PKGBUILD
    (from rev 969883, haskell-src-meta/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: haskell-src-meta/repos/community-staging-x86_64/PKGBUILD (from rev 969883, haskell-src-meta/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-01 21:34:54 UTC (rev 969884)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=haskell-src-meta
+pkgname=haskell-src-meta
+pkgver=0.8.7
+pkgrel=24
+pkgdesc="Parse source to template-haskell abstract syntax"
+url="https://github.com/bmillwood/haskell-src-meta"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-src-exts' 'haskell-syb' 'haskell-th-orphans')
+makedepends=('ghc' 'haskell-hunit' 'haskell-tasty' 'haskell-tasty-hunit')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('9a4d376be83b21b6289125a6b21dd309ebb336996f35cd72ff0e93bab7071f25b505897aa60d2f9b7809c18d6f03cb5335c2bfbf895edf4423b34801dd608f94')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}