[arch-commits] Commit in haskell-servant/repos (2 files)

[Felix Yan]

    Date: Friday, July 2, 2021 @ 07:16:36
  Author: felixonmars
Revision: 970417

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant/repos/community-staging-x86_64/
  haskell-servant/repos/community-staging-x86_64/PKGBUILD
    (from rev 970416, haskell-servant/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: haskell-servant/repos/community-staging-x86_64/PKGBUILD (from rev 970416, haskell-servant/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-02 07:16:36 UTC (rev 970417)
@@ -0,0 +1,54 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant
+pkgname=haskell-servant
+pkgver=0.18.2
+pkgrel=65
+pkgdesc="A family of combinators for defining webservices APIs"
+url="http://haskell-servant.readthedocs.org/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-attoparsec'
+         'haskell-bifunctors' 'haskell-case-insensitive' 'haskell-http-api-data'
+         'haskell-http-media' 'haskell-http-types' 'haskell-mmorph' 'haskell-network-uri'
+         'haskell-quickcheck' 'haskell-tagged' 'haskell-sop-core' 'haskell-singleton-bool'
+         'haskell-string-conversions' 'haskell-vault')
+makedepends=('ghc' 'uusi' 'haskell-hspec' 'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('97214847dc3a66d167be93ae28ab711058652b7b0201a14e7b2093b34b21c731f359f2022a6dea2a1f78ba6f27d1ea78332e5b64a03200b6c5e73c1bc44a0c88')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -u attoparsec -u base -u hspec -u http-api-data -u singleton-bool $_hkgname.cabal
+    sed -i 's/_testNubbed = id/_testNubbed a = a/' src/Servant/API/UVerb/Union.hs
+    sed -i 's/flip unSourceT return/(\\x -> unSourceT x return)/' test/Servant/API/StreamSpec.hs
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}