[arch-commits] Commit in waybar/repos (2 files)

[Maxime Gauduin]

    Date: Friday, July 2, 2021 @ 08:00:32
  Author: alucryd
Revision: 970485

archrelease: copy trunk to community-staging-x86_64

Added:
  waybar/repos/community-staging-x86_64/
  waybar/repos/community-staging-x86_64/PKGBUILD
    (from rev 970484, waybar/trunk/PKGBUILD)

----------+
 PKGBUILD |   62 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

Copied: waybar/repos/community-staging-x86_64/PKGBUILD (from rev 970484, waybar/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-02 08:00:32 UTC (rev 970485)
@@ -0,0 +1,62 @@
+# Maintainer: Brett Cornwall <ainola at archlinux.org>
+# Maintainer: Maxim Baz <$pkgname at maximbaz dot com>
+
+pkgname=waybar
+pkgver=0.9.7
+pkgrel=2
+pkgdesc='Highly customizable Wayland bar for Sway and Wlroots based compositors'
+arch=('x86_64')
+url="https://github.com/Alexays/Waybar/"
+license=('MIT')
+depends=(
+    'gtkmm3'
+    'libjsoncpp.so'
+    'libsigc++'
+    'fmt'
+    'wayland'
+    'libdate-tz.so'
+    'libspdlog.so'
+    'gtk-layer-shell'
+    'libpulse'
+    'libnl'
+    'libappindicator-gtk3'
+    'libdbusmenu-gtk3'
+    'libmpdclient'
+    'libsndio.so'
+)
+makedepends=(
+    'cmake'
+    'meson'
+    'scdoc' # For generating manpages
+    'wayland-protocols'
+)
+optdepends=(
+    'otf-font-awesome: Icons in the default configuration'
+)
+source=(
+    "$pkgname-$pkgver.tar.gz::https://github.com/Alexays/Waybar/archive/$pkgver.tar.gz"
+    "https://github.com/Alexays/Waybar/pull/1144.patch"
+)
+sha256sums=('0d23573e0f6ce6e3f3eb4d1d7313848b924429268f3becd81649a391ae7703e7'
+            '24e27ce50647cec5ad4d5e667c22b538d404fa865e8aba2a0dadac2166502a95')
+
+prepare() {
+    cd "Waybar-$pkgver"
+    patch -Np1 -i ../1144.patch
+}
+
+build() {
+    cd "Waybar-$pkgver"
+    meson --prefix=/usr \
+          --buildtype=plain \
+          --auto-features=enabled \
+          --wrap-mode=nodownload \
+          build
+    ninja -C build
+}
+
+package() {
+    cd "Waybar-$pkgver"
+    DESTDIR="$pkgdir" ninja -C build install
+    install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
+}