[arch-commits] Commit in openimageio/repos (2 files)

[Antonio Rojas]

    Date: Friday, July 2, 2021 @ 18:37:37
  Author: arojas
Revision: 970926

archrelease: copy trunk to community-staging-x86_64

Added:
  openimageio/repos/community-staging-x86_64/
  openimageio/repos/community-staging-x86_64/PKGBUILD
    (from rev 970925, openimageio/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: openimageio/repos/community-staging-x86_64/PKGBUILD (from rev 970925, openimageio/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-02 18:37:37 UTC (rev 970926)
@@ -0,0 +1,47 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: SpepS <dreamspepser at yahoo dot it>
+
+pkgname=openimageio
+pkgver=2.2.15.1
+pkgrel=4
+pkgdesc="A library for reading and writing images, including classes, utilities, and applications"
+arch=(x86_64)
+url="http://www.openimageio.org/"
+license=('custom')
+depends=('openexr' 'boost-libs' 'openjpeg2' 'glew' 'libtiff' 'opencolorio' 'libpng' 'libraw' 'libwebp'
+         'fmt' 'pugixml' 'pybind11' 'libheif' 'hdf5' 'freetype2')
+# TODO: Consider adding these deps: 'openvdb' 'ffmpeg' 'ptex' 'opencv'
+makedepends=('cmake' 'qt5-base' 'python' 'boost' 'mesa' 'fontconfig' 'libxrender' 'ninja' 'robin-map')
+optdepends=('qt5-base: iv image viewer'
+            'python: bindings support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenImageIO/oiio/archive/Release-$pkgver.tar.gz")
+sha512sums=('c06df310f91938b25f1f66cd98d995dcaba51c6a0041b47882c52f5ad4a098a9016fc99f41de250dd1b1b7af3ad22f6ed63d5e76f95f1f1cf0f45c80eee9c8e0')
+
+build() {
+  cd oiio-Release-$pkgver
+
+  cmake \
+      -Bbuild \
+      -GNinja \
+      -DUSE_PYTHON=ON \
+      -DPYTHON_VERSION=3.9 \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DCMAKE_INSTALL_LIBDIR=lib \
+      -DOIIO_BUILD_TESTS=ON \
+      -DOIIO_BUILD_TOOLS=ON \
+      -DBUILD_MISSING_FMT=OFF \
+      -DUSE_EXTERNAL_PUGIXML=ON \
+      -DSTOP_ON_WARNING=OFF
+  ninja -C build
+}
+
+package() {
+  cd oiio-Release-$pkgver
+
+  DESTDIR="$pkgdir" ninja -C build install
+
+  # Remove vendored fonts
+  rm -r "$pkgdir"/usr/share/fonts
+
+  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE".md
+}