[arch-commits] Commit in fceux/repos/community-x86_64 (PKGBUILD PKGBUILD)

[Alexander Rødseth]

    Date: Sunday, July 4, 2021 @ 14:05:41
  Author: arodseth
Revision: 972075

archrelease: copy trunk to community-x86_64

Added:
  fceux/repos/community-x86_64/PKGBUILD
    (from rev 972074, fceux/trunk/PKGBUILD)
Deleted:
  fceux/repos/community-x86_64/PKGBUILD

----------+
 PKGBUILD |   82 +++++++++++++++++++++++++++++--------------------------------
 1 file changed, 40 insertions(+), 42 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-07-04 14:05:36 UTC (rev 972074)
+++ PKGBUILD	2021-07-04 14:05:41 UTC (rev 972075)
@@ -1,42 +0,0 @@
-# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
-# Contriutor: Eric Belanger <eric at archlinux.org>
-# Contributor: Jo Christian Bergskås <jcberg at gmail.com>
-
-pkgname=fceux
-pkgver=2.3.0
-pkgrel=1
-url='https://fceux.com/'
-pkgdesc='Fast and ultra-compatible NES/Famicom emulator'
-arch=(x86_64)
-license=(GPL)
-depends=(gd minizip qt5-base sdl2)
-makedepends=(cmake git glu mesa-libgl ninja setconf scons)
-_commit='65c5b0d2a1c08db75bb41340bfa5534578926944' # fceux-2.3.0
-_url='https://github.com/TASVideos/fceux'
-source=("git+$_url#commit=$_commit")
-sha256sums=('SKIP')
-
-prepare() {
-  cd $pkgname
-  sed -i 's/-interim git//g' src/version.h
-  setconf scripts/genGitHdr.sh GIT_URL "'""$_url""'"
-  setconf scripts/genGitHdr.sh GIT_REV $_commit
-}
-
-build() {
-  mkdir -p build
-  cd build
-  cmake ../$pkgname \
-    -DCMAKE_INSTALL_PREFIX=/usr \
-    -DCMAKE_C_FLAGS="$CFLAGS -fPIC -w" \
-    -DCMAKE_CXX_FLAGS="$CXXFLAGS -fPIC -w" \
-    -G Ninja
-  ninja
-}
-
-package() {
-  DESTDIR="$pkgdir" ninja -C build install
-  install -d "$pkgdir/usr/share/doc/$pkgname"
-  cp -r $pkgname/documentation/* "$pkgdir/usr/share/doc/$pkgname/"
-  install -Dm644 $pkgname/changelog.txt "$pkgdir/usr/share/doc/$pkgname/"
-}

Copied: fceux/repos/community-x86_64/PKGBUILD (from rev 972074, fceux/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-07-04 14:05:41 UTC (rev 972075)
@@ -0,0 +1,40 @@
+# Maintainer: Alexander F. Rødseth <xyproto at archlinux.org>
+# Contriutor: Eric Belanger <eric at archlinux.org>
+# Contributor: Jo Christian Bergskås <jcberg at gmail.com>
+
+pkgname=fceux
+pkgver=2.4.0
+pkgrel=1
+url='https://fceux.com/'
+pkgdesc='Fast and ultra-compatible NES/Famicom emulator'
+arch=(x86_64)
+license=(GPL)
+depends=(gd minizip qt5-base sdl2)
+makedepends=(cmake git glu mesa-libgl ninja setconf scons)
+source=("git+https://github.com/TASVideos/fceux#commit=941da60ecb283263a3810ed199d80abf94bd6494") # fceux-2.4.0
+b2sums=('SKIP')
+
+prepare() {
+  cd $pkgname
+  sed -i 's/-interim git//g' src/version.h
+  setconf scripts/genGitHdr.sh GIT_URL "'""${source:4:34}""'"
+  setconf scripts/genGitHdr.sh GIT_REV "${source#*=}"
+}
+
+build() {
+  mkdir -p build
+  cd build
+  cmake ../$pkgname \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_C_FLAGS="$CFLAGS -fPIC -w" \
+    -DCMAKE_CXX_FLAGS="$CXXFLAGS -fPIC -w" \
+    -G Ninja
+  ninja
+}
+
+package() {
+  DESTDIR="$pkgdir" ninja -C build install
+  install -d "$pkgdir/usr/share/doc/$pkgname"
+  cp -r $pkgname/documentation/* "$pkgdir/usr/share/doc/$pkgname/"
+  install -Dm644 $pkgname/changelog.txt "$pkgdir/usr/share/doc/$pkgname/"
+}