[arch-commits] Commit in spice/repos (testing-x86_64 testing-x86_64/PKGBUILD)
Sven-Hendrik Haase
svenstaro at archlinux.org
Mon Jul 5 00:47:28 UTC 2021
Date: Monday, July 5, 2021 @ 00:47:28
Author: svenstaro
Revision: 418938
archrelease: copy trunk to testing-x86_64
Added:
spice/repos/testing-x86_64/
spice/repos/testing-x86_64/PKGBUILD
(from rev 418937, spice/trunk/PKGBUILD)
----------+
PKGBUILD | 38 ++++++++++++++++++++++++++++++++++++++
1 file changed, 38 insertions(+)
Copied: spice/repos/testing-x86_64/PKGBUILD (from rev 418937, spice/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD (rev 0)
+++ testing-x86_64/PKGBUILD 2021-07-05 00:47:28 UTC (rev 418938)
@@ -0,0 +1,38 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Maintainer: Patryk Kowalczyk < patryk at kowalczyk dot ws>
+
+pkgname=spice
+pkgver=0.15.0
+pkgrel=1
+pkgdesc="SPICE server"
+arch=('x86_64')
+url="https://www.spice-space.org"
+license=('LGPL2.1')
+depends=('pixman' 'opus' 'libjpeg-turbo' 'glib2' 'libsasl' 'lz4')
+makedepends=('meson' 'spice-protocol' 'libcacard')
+checkdepends=('gdk-pixbuf2' 'glib-networking')
+provides=('libspice-server.so')
+source=("https://www.spice-space.org/download/releases/spice-server/$pkgname-$pkgver.tar.bz2"{,.sig})
+sha256sums=('b320cf8f4bd2852750acb703c15b72856027e5a8554f8217dfbb3cc09deba0f5'
+ 'SKIP')
+validpgpkeys=('206D3B352F566F3B0E6572E997D9123DE37A484F') # Victor Toso <victortoso at redhat.com>
+
+prepare() {
+ sed -i "s/if not version_info.contains('git')/if version_info.length() >= 4/" $pkgname-$pkgver/server/meson.build
+ # Consider removing the following sed once this issue is resolved:
+ # https://gitlab.freedesktop.org/spice/spice/-/issues/62
+ sed -i "/doxygen.sh/d" $pkgname-$pkgver/meson.build
+}
+
+build() {
+ arch-meson "$pkgname-$pkgver" build -D gstreamer=no
+ ninja -C build
+}
+
+check() {
+ meson test -C build --print-errorlogs
+}
+
+package() {
+ DESTDIR="$pkgdir" meson install -C build
+}
More information about the arch-commits
mailing list