[arch-commits] Commit in git-delta/repos (community-x86_64 community-x86_64/PKGBUILD)

[George Rawlinson]

    Date: Thursday, July 8, 2021 @ 09:37:11
  Author: grawlinson
Revision: 975765

archrelease: copy trunk to community-x86_64

Added:
  git-delta/repos/community-x86_64/
  git-delta/repos/community-x86_64/PKGBUILD
    (from rev 975764, git-delta/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: git-delta/repos/community-x86_64/PKGBUILD (from rev 975764, git-delta/trunk/PKGBUILD)
===================================================================
--- community-x86_64/PKGBUILD	                        (rev 0)
+++ community-x86_64/PKGBUILD	2021-07-08 09:37:11 UTC (rev 975765)
@@ -0,0 +1,53 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor:  Kr1ss $(echo \<kr1ss+x-yandex+com\>|sed s/\+/./g\;s/\-/@/)
+# Contributor : ccorn
+
+pkgname=git-delta
+_pkgname=delta
+pkgver=0.8.2
+pkgrel=2
+pkgdesc='Syntax-highlighting pager for git and diff output'
+arch=('x86_64')
+url="https://github.com/dandavison/delta"
+license=('MIT')
+depends=('libgit2')
+makedepends=('rust')
+checkdepends=('git')
+optdepends=(
+  'bash-completion: for shell auto-completion'
+  'zsh-completions: for shell auto-completion'
+)
+options=('!lto')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+b2sums=('86d60df2bd5a42969a44dd7239ab6a6502030ab10fa7dab18ff91192843d3817b2af475765691bfae43897e9111446ba49242de48f2bcafb69df6fb569f226c0')
+
+build() {
+  cd "$_pkgname-$pkgver"
+  RUSTUP_TOOLCHAIN=stable cargo build --release --locked --all-features --target-dir=target
+}
+
+check() {
+  cd "$_pkgname-$pkgver"
+  # some tests hang for 60+ seconds, find out why
+  # took my machine ~ 470 seconds
+  RUSTUP_TOOLCHAIN=stable cargo test --locked --target-dir=target
+}
+
+package() {
+  cd "$_pkgname-$pkgver"
+  
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/delta
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+
+  # shell auto-completions
+  install -vDm644 etc/completion/completion.bash \
+    "$pkgdir/usr/share/bash-completion/completions/$_pkgname"
+  install -vDm644 etc/completion/completion.zsh \
+    "$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+}