[arch-commits] Commit in dolphin-emu/repos (2 files)

[Antonio Rojas]

    Date: Friday, July 9, 2021 @ 18:36:32
  Author: arojas
Revision: 976268

archrelease: copy trunk to community-staging-x86_64

Added:
  dolphin-emu/repos/community-staging-x86_64/
  dolphin-emu/repos/community-staging-x86_64/PKGBUILD
    (from rev 976267, dolphin-emu/trunk/PKGBUILD)

----------+
 PKGBUILD |   74 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 74 insertions(+)

Copied: dolphin-emu/repos/community-staging-x86_64/PKGBUILD (from rev 976267, dolphin-emu/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-09 18:36:32 UTC (rev 976268)
@@ -0,0 +1,74 @@
+# Maintainer: schuay <jakob.gruber at gmail.com>
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Jeremy Newton (Mystro256) <alexjnewt at gmail.com>
+
+pkgname=dolphin-emu
+pkgver=5.0.r14344.acc7d3710d
+pkgrel=2
+epoch=1
+pkgdesc='A Gamecube / Wii / Triforce emulator'
+arch=(x86_64)
+url=https://dolphin-emu.org
+license=(GPL2)
+depends=(
+  alsa-lib
+  bluez-libs
+  enet
+  gcc-libs
+  glibc
+  hidapi
+  libavcodec.so
+  libavformat.so
+  libavutil.so
+  libcurl.so
+  libevdev
+  libgl
+  libminiupnpc.so
+  libpng
+  libpulse
+  libswscale.so
+  libudev.so
+  libusb-1.0.so
+  libx11
+  libxi
+  libxrandr
+  lzo
+  mbedtls
+  pugixml
+  qt5-base
+  sfml
+  zlib
+)
+makedepends=(
+  cmake
+  git
+  python
+)
+optdepends=('pulseaudio: PulseAudio backend')
+options=(!emptydirs)
+_commit=acc7d3710d60552769f61f4b44bc8533a940df36
+source=(dolphin-emu::git+https://github.com/dolphin-emu/dolphin.git#commit=${_commit})
+sha256sums=(SKIP)
+
+pkgver() {
+  cd dolphin-emu
+
+  git describe | sed 's/-/.r/; s/-g/./'
+}
+
+build() {
+  cmake -S dolphin-emu -B build \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DUSE_SHARED_ENET=ON \
+    -DDISTRIBUTOR=archlinux.org
+  make -C build
+}
+
+package() {
+  make DESTDIR="${pkgdir}" -C build install
+  install -Dm 644 dolphin-emu/Data/51-usb-device.rules -t "${pkgdir}"/usr/lib/udev/rules.d/
+  rm -rf "${pkgdir}"/usr/{include,lib/libdiscord-rpc.a}
+}
+
+# vim: ts=2 sw=2 et: