[arch-commits] Commit in scons/repos (testing-any testing-any/PKGBUILD)

[David Runge]

    Date: Tuesday, July 13, 2021 @ 08:43:37
  Author: dvzrv
Revision: 419663

archrelease: copy trunk to testing-any

Added:
  scons/repos/testing-any/
  scons/repos/testing-any/PKGBUILD
    (from rev 419662, scons/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: scons/repos/testing-any/PKGBUILD (from rev 419662, scons/trunk/PKGBUILD)
===================================================================
--- testing-any/PKGBUILD	                        (rev 0)
+++ testing-any/PKGBUILD	2021-07-13 08:43:37 UTC (rev 419663)
@@ -0,0 +1,52 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Ray Rashif <schiv at archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+# Contributor: Lukas Sabota <punkrockguy318 at comcast.net>
+# Contributor: Brice Carpentier <brice at dlfp.org>
+
+pkgname=scons
+pkgver=4.1.0
+pkgrel=1
+pkgdesc="Extensible Python-based build utility"
+arch=('any')
+url="https://scons.org"
+license=('MIT')
+depends=('python')
+makedepends=('python-setuptools' 'python-sphinx' 'python-sphinx_rtd_theme'
+'rst2pdf')
+checkdepends=('python-pytest')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/${pkgname}/${pkgname}/archive/${pkgver}.tar.gz")
+sha512sums=('f79b86bb09783767b3872cfb8efb665372714a604af2aaf3adc66eee63d3afe27bc6b2aab83813743c83f71c81c800d42842e916501787ba402ce2726dda9b44')
+b2sums=('ede3d47a1ec652b9248681e26738073e9d01daab7ffeccc58f0fcadb79661e30edb9a35a511518e4a58459243acb027afd8fa5849b0f9e4bae451055f7b1a062')
+
+prepare() {
+  cd "${pkgname}-${pkgver}"
+  # fixing ancient target in SConstruct
+  sed -e 's/bdist_wheel/bdist/g' -i SConstruct
+}
+
+build() {
+  cd "${pkgname}-${pkgver}"
+  python scripts/scons.py --include-dir= -j1
+}
+
+check() {
+  cd "${pkgname}-${pkgver}"
+  python runtest.py --all --unit-only
+}
+
+package() {
+  cd "${pkgname}-${pkgver}"
+  python setup.py install --prefix=/usr \
+                          --skip-build \
+                          --optimize=1 \
+                          --install-data=/usr/share \
+                          --root="$pkgdir"
+  install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
+  install -vDm 644 {{CHANGES,RELEASE}.txt,README.rst} \
+    -t "${pkgdir}/usr/share/doc/${pkgname}/"
+
+  #move man pages to correct location from /usr/share/
+  install -vdm 755 "${pkgdir}/usr/share/man/man1"
+  mv -v "${pkgdir}/usr/share/"*.1 "${pkgdir}/usr/share/man/man1"
+}