[arch-commits] Commit in haskell-yesod/repos (2 files)

[Felix Yan]

    Date: Friday, July 16, 2021 @ 04:13:48
  Author: felixonmars
Revision: 977485

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-yesod/repos/community-staging-x86_64/
  haskell-yesod/repos/community-staging-x86_64/PKGBUILD
    (from rev 977484, haskell-yesod/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-yesod/repos/community-staging-x86_64/PKGBUILD (from rev 977484, haskell-yesod/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-16 04:13:48 UTC (rev 977485)
@@ -0,0 +1,47 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=yesod
+pkgname=haskell-yesod
+pkgver=1.6.1.2
+pkgrel=11
+pkgdesc="Creation of type-safe, RESTful web applications."
+url="http://www.yesodweb.com/"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-conduit' 'haskell-data-default-class'
+         'haskell-fast-logger' 'haskell-file-embed' 'haskell-monad-logger' 'haskell-shakespeare'
+         'haskell-streaming-commons' 'haskell-unordered-containers' 'haskell-wai'
+         'haskell-wai-extra' 'haskell-wai-logger' 'haskell-warp' 'haskell-yaml'
+         'haskell-yesod-core' 'haskell-yesod-form' 'haskell-yesod-persistent')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a062f74502c5d88784a20f3bbe4c5799475043f3d17fea28b8199e9e4a3f9cc044e7b21a97bdb0c7e9e91c6e76aec4350a2cddc6306afb7c2f78f347ebf4f249')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}