[arch-commits] Commit in runc/repos (2 files)

[Frederik Schwan]

    Date: Friday, July 16, 2021 @ 18:06:56
  Author: freswa
Revision: 977715

archrelease: copy trunk to community-testing-x86_64

Added:
  runc/repos/community-testing-x86_64/
  runc/repos/community-testing-x86_64/PKGBUILD
    (from rev 977714, runc/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: runc/repos/community-testing-x86_64/PKGBUILD (from rev 977714, runc/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-07-16 18:06:56 UTC (rev 977715)
@@ -0,0 +1,55 @@
+# Maintainer: Morten Linderud <foxboron at archlinux.org>
+# Maintainer: Frederik Schwan <freswa at archlinux dot org>
+# Contributor: Sébastien "Seblu" Luttringer
+
+pkgname=runc
+pkgver=1.0.1
+pkgrel=1
+pkgdesc='CLI tool for managing OCI compliant containers'
+arch=(x86_64)
+url='https://runc.io/'
+license=(Apache)
+depends=(libseccomp)
+makedepends=(git go go-md2man)
+opdepends=(
+  'criu: checkpoint support'
+)
+_commit=47e597c3eb2f002299eb9be6c8476194a92e9595	#refs/tags/v1.0.0^{}
+# source=("git+https://github.com/opencontainers/runc.git#commit=$_commit?signed")
+source=("git+https://github.com/opencontainers/runc.git#tag=v${pkgver}?signed")
+validpgpkeys=("5F36C6C61B5460124A75F5A69E18AA267DDB8DB4"
+			  "C9C370B246B09F6DBCFC744C34401015D1D2D386")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd runc
+  git describe | sed 's/^v//;s/-//;s/-/+/g'
+}
+
+prepare() {
+  mkdir -p src/github.com/opencontainers
+  cp -r runc src/github.com/opencontainers/
+}
+
+build() {
+  cd src/github.com/opencontainers/runc
+  export GOPATH="$srcdir"
+  export BUILDTAGS='seccomp apparmor'
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-trimpath -mod=readonly -modcacherw"
+  make runc man
+}
+
+package() {
+  cd src/github.com/opencontainers/runc
+
+  install -Dm755 runc "$pkgdir/usr/bin/runc"
+  install -Dm644 contrib/completions/bash/runc \
+    "$pkgdir/usr/share/bash-completion/completions/runc"
+  
+  install -d "$pkgdir/usr/share/man/man8"
+  install -m644 man/man8/*.8 "$pkgdir/usr/share/man/man8"
+}