[arch-commits] Commit in libfilezilla/repos (2 files)

[Frederik Schwan]

    Date: Friday, July 16, 2021 @ 23:57:45
  Author: freswa
Revision: 977746

archrelease: copy trunk to community-testing-x86_64

Added:
  libfilezilla/repos/community-testing-x86_64/
  libfilezilla/repos/community-testing-x86_64/PKGBUILD
    (from rev 977745, libfilezilla/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: libfilezilla/repos/community-testing-x86_64/PKGBUILD (from rev 977745, libfilezilla/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-07-16 23:57:45 UTC (rev 977746)
@@ -0,0 +1,41 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Florian Pritz <bluewind at xinu.at>
+# Contributor: Martchus <martchus at gmx.net>
+
+pkgname=libfilezilla
+pkgver=0.30.0
+pkgrel=1
+pkgdesc='Small and modern C++ library, offering some basic functionality to build high-performing, platform-independent programs'
+url='https://lib.filezilla-project.org/'
+arch=('x86_64')
+license=('GPL')
+depends=('glibc' 'gcc-libs' 'nettle' 'gnutls' 'libnettle.so' 'libhogweed.so')
+makedepends=(clang)
+checkdepends=('cppunit')
+provides=('libfilezilla.so')
+source=(https://download.filezilla-project.org/libfilezilla/libfilezilla-${pkgver}.tar.bz2)
+sha512sums=('f05a1ef2be7a6d32a6c5adf8e02f2b17e83deb67bf7c67b1bc1fec539a7235903d91dd3e98412aa1b90f1fcb322cb9ab54d3a1ff4ec44889b4dcdda6984300c9')
+b2sums=('abfef274989b0ba31d9237394aa1e88012e9fe9d071c11e7350e0ada8d5da54d7cdc93f46f65b38fa9a811a638210238f42de99fdd6832f97ede3808723e5d4f')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  export CXX=clang++
+  export CC=clang
+  ./configure \
+    --prefix=/usr \
+    --disable-static
+  make
+}
+
+check() {
+  cd ${pkgname}-${pkgver}
+  # LANG needed to fix string_test::test_conversion2
+  LANG=en_US.UTF-8 make check
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make DESTDIR="${pkgdir}" install
+}
+
+# vim: ts=2 sw=2 et: