[arch-commits] Commit in sequoia/repos (2 files)

[Frederik Schwan]

    Date: Saturday, July 17, 2021 @ 01:12:55
  Author: freswa
Revision: 977757

archrelease: copy trunk to community-testing-x86_64

Added:
  sequoia/repos/community-testing-x86_64/
  sequoia/repos/community-testing-x86_64/PKGBUILD
    (from rev 977756, sequoia/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: sequoia/repos/community-testing-x86_64/PKGBUILD (from rev 977756, sequoia/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-07-17 01:12:55 UTC (rev 977757)
@@ -0,0 +1,57 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Kai Michaelis <kai at sequoia-pgp.org>
+
+pkgbase=sequoia
+pkgname=(sequoia python-sequoia)
+pkgver=1.3.0
+pkgrel=1
+pkgdesc='Cool new OpenPGP implementation'
+url='https://sequoia-pgp.org/'
+arch=('x86_64')
+license=('GPL3')
+makedepends=('git' 'cargo' 'clang' 'python' 'python-setuptools' 'python-cffi'
+             'glibc' 'nettle' 'sqlite' 'capnproto' 'openssl' 'gcc-libs' 'gmp'
+             'bzip2' 'libbz2.so')
+checkdepends=('python-pytest' 'python-pytest-runner')
+options=('!makeflags')
+source=(${pkgname}::"git+https://gitlab.com/sequoia-pgp/sequoia.git#tag=openpgp/v${pkgver}")
+sha512sums=('SKIP')
+
+prepare() {
+  cd ${pkgname}
+  sed 's/debug/release/g' -i -- */Makefile */*/Makefile */*/*/Makefile
+  sed "s/-L/${LDFLAGS},-L/g" -i ffi/lang/python/Makefile
+  ln -s .Makefile Makefile
+}
+
+build() {
+  cd ${pkgname}
+  make PREFIX=/usr CARGO_FLAGS='--locked' build-release
+}
+
+check() {
+  cd ${pkgname}
+  cargo test --release --locked \
+    --workspace \
+    --exclude sequoia-store
+  # python tests currently fail horribly
+  # make -C ffi/lang/python test
+}
+
+package_sequoia() {
+  depends=('glibc' 'nettle' 'libhogweed.so' 'libnettle.so' 'sqlite' 'capnproto'
+           'openssl' 'gcc-libs' 'gmp' 'bzip2' 'libbz2.so')
+  cd ${pkgbase}
+  make DESTDIR="${pkgdir}" PREFIX=/usr CARGO_FLAGS='--locked' install
+  install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
+  rm -rf "${pkgdir}/usr/lib/python"*
+}
+
+package_python-sequoia() {
+  depends=('python' 'python-cffi' 'sequoia')
+  pkgdesc+=' - python bindings'
+  cd ${pkgbase}
+  make -C ffi/lang/python DESTDIR="${pkgdir}" PREFIX=/usr install
+}
+
+# vim: ts=2 sw=2 et: