[arch-commits] Commit in fmt/repos (3 files)

David Runge dvzrv at gemini.archlinux.org
Sat Jul 17 20:22:09 UTC 2021


    Date: Saturday, July 17, 2021 @ 20:22:09
  Author: dvzrv
Revision: 420077

archrelease: copy trunk to staging-x86_64

Added:
  fmt/repos/staging-x86_64/
  fmt/repos/staging-x86_64/PKGBUILD
    (from rev 420076, fmt/trunk/PKGBUILD)
  fmt/repos/staging-x86_64/dont-install-doctrees.patch
    (from rev 420076, fmt/trunk/dont-install-doctrees.patch)

-----------------------------+
 PKGBUILD                    |   60 ++++++++++++++++++++++++++++++++++++++++++
 dont-install-doctrees.patch |   24 ++++++++++++++++
 2 files changed, 84 insertions(+)

Copied: fmt/repos/staging-x86_64/PKGBUILD (from rev 420076, fmt/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-07-17 20:22:09 UTC (rev 420077)
@@ -0,0 +1,60 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Mihai Bişog <mihai.bisog at gmail.com>
+
+pkgname=fmt
+pkgver=8.0.1
+pkgrel=1
+pkgdesc='Open-source formatting library for C++'
+arch=(x86_64)
+url=https://fmt.dev
+license=(BSD)
+depends=(gcc-libs)
+makedepends=(
+  cmake
+  doxygen
+  git
+  ninja
+  npm
+  python-pip
+  python-virtualenv
+)
+provides=(libfmt.so)
+_commit=d141cdbeb0fb422a3fb7173b285fd38e0d1772dc
+source=(git+https://github.com/fmtlib/fmt.git#commit=${_commit})
+b2sums=('SKIP')
+
+prepare() {
+  pushd fmt
+  # https://github.com/fmtlib/fmt/pull/2376
+  git cherry-pick -n c9a10631cb3a656b0a0a3ba3cf0ef7ea541df30f
+  popd
+
+  npm install less less-plugin-clean-css
+  sed "s/'lessc',/'npx', 'lessc',/" -i fmt/doc/build.py
+}
+
+pkgver() {
+  cd fmt
+  git describe --tags
+}
+
+build() {
+  cmake -S fmt -B build -G Ninja \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
+    -DBUILD_SHARED_LIBS=1
+  cmake --build build
+  cmake --build build --target doc
+}
+
+check() {
+  cmake --build build --target test
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --build build --target install
+  install -Dm 644 fmt/LICENSE.rst -t "${pkgdir}"/usr/share/licenses/fmt
+}
+
+# vim: ts=2 sw=2 et:

Copied: fmt/repos/staging-x86_64/dont-install-doctrees.patch (from rev 420076, fmt/trunk/dont-install-doctrees.patch)
===================================================================
--- staging-x86_64/dont-install-doctrees.patch	                        (rev 0)
+++ staging-x86_64/dont-install-doctrees.patch	2021-07-17 20:22:09 UTC (rev 420077)
@@ -0,0 +1,24 @@
+From 8f2b5fe74d34ba8bb20a362a4daa6cc5a99a2010 Mon Sep 17 00:00:00 2001
+From: Jelle van der Waa <jelle at vdwaa.nl>
+Date: Fri, 29 May 2020 23:19:16 +0200
+Subject: [PATCH] Don't install sphinx cache files
+
+When building documentation sphinx creates cached files in the .doctrees
+directory and aren't required for viewing documentation only for
+building. As added benefit this makes fmt reprodcubile as the cached
+files are different when the build environment is varied.
+---
+ doc/CMakeLists.txt | 3 ++-
+ 1 file changed, 2 insertions(+), 1 deletion(-)
+
+diff --git a/doc/CMakeLists.txt b/doc/CMakeLists.txt
+index f3dae606e..108aa71e8 100644
+--- a/doc/CMakeLists.txt
++++ b/doc/CMakeLists.txt
+@@ -9,4 +9,5 @@ add_custom_target(doc
+   SOURCES api.rst syntax.rst usage.rst build.py conf.py _templates/layout.html)
+ 
+ install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/html/
+-        DESTINATION share/doc/fmt OPTIONAL)
++        DESTINATION share/doc/fmt OPTIONAL
++        PATTERN ".doctrees" EXCLUDE)




More information about the arch-commits mailing list