[arch-commits] Commit in (peco peco/repos peco/trunk peco/trunk/PKGBUILD)

[George Rawlinson]

    Date: Sunday, July 18, 2021 @ 22:53:10
  Author: grawlinson
Revision: 978537

addpkg: peco 0.5.10-3

Added:
  peco/
  peco/repos/
  peco/trunk/
  peco/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: peco/trunk/PKGBUILD
===================================================================
--- peco/trunk/PKGBUILD	                        (rev 0)
+++ peco/trunk/PKGBUILD	2021-07-18 22:53:10 UTC (rev 978537)
@@ -0,0 +1,49 @@
+# Maintainer: George Rawlinson <grawlinson at archlinux.org>
+# Contributor: Morteza NourelahiAlamdari <m at 0t1.me>
+# Contributor: Samuel Walladge <aur at swalladge dot net>
+
+pkgname=peco
+pkgver=0.5.10
+pkgrel=3
+pkgdesc='Simplistic interactive filtering tool'
+arch=('x86_64')
+url='https://github.com/peco/peco'
+license=('MIT')
+makedepends=('go')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
+b2sums=('927039707f36bb285aefccecbf1643d2728f7e90deb2f46793ff2d0b1c60d6d71a0d89c13132d6e8901257ca1b726cee36b64e6160230b5aa6e5b84e22f25c3d')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+  mkdir -p build
+}
+build() {
+  cd "$pkgname-$pkgver"
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+
+  go build -v \
+    -trimpath \
+    -buildmode=pie \
+    -mod=readonly \
+    -modcacherw \
+    -ldflags "-linkmode external -extldflags \"${LDFLAGS}\"" \
+    -o build ./cmd/...
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" "build/$pkgname"
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+}
+
+# vim:set ts=2 sw=2 et: