[arch-commits] Commit in cgns/repos (2 files)

[Bruno Pagani]

    Date: Monday, July 19, 2021 @ 22:25:01
  Author: archange
Revision: 978952

archrelease: copy trunk to community-staging-x86_64

Added:
  cgns/repos/community-staging-x86_64/
  cgns/repos/community-staging-x86_64/PKGBUILD
    (from rev 978951, cgns/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: cgns/repos/community-staging-x86_64/PKGBUILD (from rev 978951, cgns/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-19 22:25:01 UTC (rev 978952)
@@ -0,0 +1,44 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_pkgname=CGNS
+pkgname=cgns
+pkgver=4.2.0
+pkgrel=1
+pkgdesc="Standard for recording and recovering computer data associated with the numerical solution of fluid dynamics equations"
+arch=(x86_64)
+url="https://cgns.github.io/"
+license=(custom)
+depends=(tk hdf5 libxmu glu)
+makedepends=(gcc-fortran cmake)
+options=(!makeflags)
+source=(https://github.com/${_pkgname}/${_pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('090ec6cb0916d90c16790183fc7c2bd2bd7e9a5e3764b36c8196ba37bf1dc817')
+
+
+build() {
+    cmake -B build -S ${_pkgname}-${pkgver} \
+        -DCGNS_BUILD_CGNSTOOLS=ON \
+        -DCGNS_BUILD_SHARED=ON \
+        -DCGNS_ENABLE_64BIT=ON \
+        -DCGNS_ENABLE_FORTRAN=ON \
+        -DCGNS_ENABLE_HDF5=ON \
+        -DCGNS_ENABLE_LEGACY=ON \
+        -DCGNS_ENABLE_SCOPING=OFF \
+        -DCGNS_ENABLE_TESTS=ON \
+        -DCMAKE_BUILD_TYPE="Release" \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_SKIP_RPATH=ON
+    make -C build
+}
+
+
+check() {
+    LD_LIBRARY_PATH="${srcdir}"/build/src/ make -C build test
+}
+
+package() {
+    make -C build DESTDIR="${pkgdir}" install
+    install -Dm644 ${_pkgname}-${pkgver}/license.txt -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+    # Remove broken .desktop files
+    rm "${pkgdir}"/usr/bin/*.desktop
+}