[arch-commits] Commit in (4 files)
Jelle van der Waa
jelle at gemini.archlinux.org
Tue Jul 20 08:36:34 UTC 2021
Date: Tuesday, July 20, 2021 @ 08:36:33
Author: jelle
Revision: 979428
extra2community: Moving python2-numpy from extra to community
Added:
python2-numpy/
python2-numpy/repos/
python2-numpy/trunk/
python2-numpy/trunk/PKGBUILD
----------+
PKGBUILD | 39 +++++++++++++++++++++++++++++++++++++++
1 file changed, 39 insertions(+)
Added: python2-numpy/trunk/PKGBUILD
===================================================================
--- python2-numpy/trunk/PKGBUILD (rev 0)
+++ python2-numpy/trunk/PKGBUILD 2021-07-20 08:36:33 UTC (rev 979428)
@@ -0,0 +1,39 @@
+# Maintainer: Jan de Groot <jgc at archlinux.org>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Douglas Soares de Andrade <dsa at aur.archlinux.org>
+# Contributor: Angel 'angvp' Velasquez <angvp[at]archlinux.com.ve>
+
+pkgname=python2-numpy
+pkgver=1.16.6
+pkgrel=1
+pkgdesc="Scientific tools for Python 2"
+arch=('x86_64')
+license=('custom')
+url="https://www.numpy.org/"
+depends=('cblas' 'lapack' 'python2')
+optdepends=('openblas: faster linear algebra')
+makedepends=('python2-setuptools' 'gcc-fortran' 'cython2')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/numpy/numpy/archive/v$pkgver.tar.gz")
+sha512sums=('27344ae10c7e7fd222b34d1514aaccbb62d1322cc79bec28f5c1e8741eefbb6bc7664055e49ed4f08d5716ca93d4c997fb98bee26a19957543ab4f8c15cd41f7')
+
+prepare() {
+ cd numpy-$pkgver
+ sed -e "s|#![ ]*/usr/bin/python$|#!/usr/bin/python2|" \
+ -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" \
+ -e "s|#![ ]*/bin/env python$|#!/usr/bin/env python2|" \
+ -i $(find . -name '*.py')
+}
+
+build() {
+ cd numpy-$pkgver
+ python2 setup.py build
+}
+
+package() {
+ cd numpy-$pkgver
+ python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
+
+ install -Dm644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/python2-numpy/"
+
+ mv "$pkgdir"/usr/bin/f2py{,2}
+}
Property changes on: python2-numpy/trunk/PKGBUILD
___________________________________________________________________
Added: svn:executable
## -0,0 +1 ##
+*
\ No newline at end of property
More information about the arch-commits
mailing list