[arch-commits] Commit in netcdf-fortran/repos (2 files)

[Bruno Pagani]

    Date: Wednesday, July 21, 2021 @ 22:37:52
  Author: archange
Revision: 982768

archrelease: copy trunk to community-staging-x86_64

Added:
  netcdf-fortran/repos/community-staging-x86_64/
  netcdf-fortran/repos/community-staging-x86_64/PKGBUILD
    (from rev 982767, netcdf-fortran/trunk/PKGBUILD)

----------+
 PKGBUILD |   40 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)

Copied: netcdf-fortran/repos/community-staging-x86_64/PKGBUILD (from rev 982767, netcdf-fortran/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-21 22:37:52 UTC (rev 982768)
@@ -0,0 +1,40 @@
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Maintainer: Ronald van Haren <ronald.archlinux.org>
+# Contributor: damir <damir at archlinux.org>
+
+pkgname=netcdf-fortran
+pkgver=4.5.3
+pkgrel=2
+pkgdesc="NetCDF fortran bindings"
+arch=(x86_64)
+url="https://github.com/Unidata/netcdf-fortran"
+license=(custom)
+depends=(gcc-libs netcdf curl)
+makedepends=(cmake gcc-fortran doxygen)
+checkdepends=(valgrind)
+options=(!makeflags staticlibs)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('c6da30c2fe7e4e614c1dff4124e857afbd45355c6798353eccfa60c0702b495a')
+
+build() {
+    # Failure with GCC 10+
+    export FCFLAGS="-fallow-argument-mismatch"
+    export FFLAGS="-fallow-argument-mismatch"
+    cmake -B build -S ${pkgname}-${pkgver} \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -DCMAKE_BUILD_TYPE=Release \
+        -DENABLE_FILTER_TEST=ON \
+        -DENABLE_LARGE_FILE_TESTS=ON \
+        -DTEST_WITH_VALGRIND=ON
+    make -C build
+}
+
+check() {
+    make -C build test
+}
+
+package() {
+    make -C build DESTDIR="${pkgdir}" install
+    install -Dm644 ${pkgname}-${pkgver}/COPYRIGHT -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+    rmdir "${pkgdir}"/usr/include/CMakeFiles/{netcdff.dir,}
+}