[arch-commits] Commit in (3 files)

[Maxime Gauduin]

    Date: Friday, July 23, 2021 @ 08:50:00
  Author: alucryd
Revision: 984213

add pantheon-mail

Added:
  pantheon-mail/
  pantheon-mail/trunk/
  pantheon-mail/trunk/PKGBUILD

----------+
 PKGBUILD |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

Added: pantheon-mail/trunk/PKGBUILD
===================================================================
--- pantheon-mail/trunk/PKGBUILD	                        (rev 0)
+++ pantheon-mail/trunk/PKGBUILD	2021-07-23 08:50:00 UTC (rev 984213)
@@ -0,0 +1,48 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Contributor: Filipe Laíns (FFY00) <filipe.lains at gmail.com>
+# Contributor: Riley Trautman <asonix at tamu.edu>
+
+pkgname=pantheon-mail
+pkgver=6.0.0
+pkgrel=1
+pkgdesc='Mail app designed for elementary OS'
+arch=(x86_64)
+url=https://github.com/elementary/mail
+license=(GPL3)
+groups=(pantheon)
+depends=(
+  glib2
+  gtk3
+  libcamel-1.2.so
+  libedataserver-1.2.so
+  libedataserverui-1.2.so
+  libfolks.so
+  libgranite.so
+  libhandy-1.so
+  webkit2gtk
+)
+makedepends=(
+  git
+  intltool
+  meson
+  vala
+)
+_tag=32807ce703de125fedf9aff11a68d0d0db9914e6
+source=(pantheon-mail::git+https://github.com/elementary/mail.git#tag=${_tag})
+sha256sums=('SKIP')
+
+pkgver() {
+  cd pantheon-mail
+  git describe --tags
+}
+
+build() {
+  arch-meson pantheon-mail build
+  meson compile -C build
+}
+
+package() {
+  DESTDIR="${pkgdir}" meson install -C build
+}
+
+# vim: ts=2 sw=2 et: