[arch-commits] Commit in carla/repos (2 files)

[David Runge]

    Date: Monday, July 26, 2021 @ 17:39:50
  Author: dvzrv
Revision: 985573

archrelease: copy trunk to community-staging-x86_64

Added:
  carla/repos/community-staging-x86_64/
  carla/repos/community-staging-x86_64/PKGBUILD
    (from rev 985571, carla/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: carla/repos/community-staging-x86_64/PKGBUILD (from rev 985571, carla/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-07-26 17:39:50 UTC (rev 985573)
@@ -0,0 +1,50 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Llewelyn Trahaearn <WoefulDerelict [at] GMail [dot] com>
+# Contributor: falkTX <falktx [at] gmail [dot] com>
+
+_name=Carla
+pkgname=carla
+pkgver=2.3.1
+pkgrel=2
+pkgdesc="Audio Plugin Host"
+arch=('x86_64')
+url="https://kxstudio.linuxaudio.org/Applications:Carla"
+license=('GPL2')
+groups=('pro-audio')
+depends=('gcc-libs' 'glibc' 'libglvnd' 'libx11' 'python-pyqt5' 'python-pyliblo'
+'python-rdflib' 'qt5-base' 'qt5-svg')
+makedepends=('alsa-lib' 'file' 'fluidsynth' 'git' 'glib2' 'gtk2' 'gtk3'
+'libsndfile' 'liblo' 'libpulse' 'qt5-tools')
+optdepends=(
+  'lv2-host: for the LV2 plugin'
+  'vst-host: for the VST plugin'
+)
+provides=('dssi-host' 'ladspa-host' 'lv2-host' 'vst-host' 'vst3-host')
+source=("git+https://github.com/falkTX/${pkgname}#tag=v${pkgver}?signed")
+sha512sums=('SKIP')
+b2sums=('SKIP')
+validpgpkeys=('62B11043D2F6EB6672D93103CDBAA37ABC74FBA0')  # falkTX <falktx at falktx.com>
+
+build() {
+  cd "${pkgname}"
+  make features
+  make
+}
+
+package() {
+  # libpulse is linked against in carla/libcarla_standalone2.so
+  # liblo is linked against in carla/libcarla_standalone2.so,
+  # carla/libcarla_native-plugin.so and the lv2 and vst plugins
+  depends+=('libasound.so' 'libfluidsynth.so' 'libgdk-3.so'
+  'libgdk-x11-2.0.so' 'libgobject-2.0.so' 'libglib-2.0.so' 'libgtk-3.so'
+  'libgtk-x11-2.0.so' 'liblo.so' 'libmagic.so' 'libpulse.so'
+  'libpulse-simple.so' 'libsndfile.so')
+
+  cd "${pkgname}"
+  make DEFAULT_QT=5 \
+       DESTDIR="${pkgdir}/" \
+       PREFIX=/usr \
+       install
+  install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}/"
+}
+# vim:set ts=2 sw=2 et: