[arch-commits] Commit in netfilter-fullconenat/repos (2 files)

Jan Steffens heftig at gemini.archlinux.org
Sat Jul 31 23:13:42 UTC 2021


    Date: Saturday, July 31, 2021 @ 23:13:42
  Author: heftig
Revision: 991567

archrelease: copy trunk to community-testing-x86_64

Added:
  netfilter-fullconenat/repos/community-testing-x86_64/
  netfilter-fullconenat/repos/community-testing-x86_64/PKGBUILD
    (from rev 991564, netfilter-fullconenat/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: netfilter-fullconenat/repos/community-testing-x86_64/PKGBUILD (from rev 991564, netfilter-fullconenat/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-07-31 23:13:42 UTC (rev 991567)
@@ -0,0 +1,43 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Edward Pacman <edward at edward-p.xyz>
+
+pkgname=netfilter-fullconenat
+pkgver=r73.0cf3b48
+pkgrel=135
+pkgdesc="A kernel module that turns MASQUERADE into full cone SNAT"
+arch=('x86_64')
+url="https://github.com/Chion82/netfilter-full-cone-nat"
+license=('GPL2')
+depends=("linux")
+makedepends=('linux-headers' 'git')
+_commit=0cf3b48fd7d2fa81d0297d1fff12bbd0580fc435  # master
+source=("${pkgname}::git+https://github.com/Chion82/netfilter-full-cone-nat#commit=${_commit}")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd ${pkgname}
+  ( set -o pipefail
+    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
+    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+  )
+}
+
+prepare() {
+  cd ${pkgname}
+  echo "obj-m = xt_FULLCONENAT.o" > Kbuild
+}
+
+build() {
+  cd ${pkgname}
+  make -C /usr/src/linux M=$PWD modules
+}
+
+package() {
+  local extradir=/usr/lib/modules/$(</usr/src/linux/version)/extramodules
+  install -Dt "${pkgdir}${extradir}" -m644 ${pkgname}/*.ko
+  find "${pkgdir}" -name '*.ko' -exec strip --strip-debug {} +
+  find "${pkgdir}" -name '*.ko' -exec xz {} +
+
+  echo "xt_FULLCONENAT" | \
+    install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modules-load.d/${pkgname}.conf"
+}



More information about the arch-commits mailing list