[arch-commits] Commit in fcitx5-pinyin-zhwiki/trunk (PKGBUILD)
Felix Yan
felixonmars at archlinux.org
Fri Jun 4 21:17:57 UTC 2021
Date: Friday, June 4, 2021 @ 21:17:56
Author: felixonmars
Revision: 955944
upgpkg: fcitx5-pinyin-zhwiki 1:0.2.3.20210605-1
Added:
fcitx5-pinyin-zhwiki/trunk/PKGBUILD
----------+
PKGBUILD | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 50 insertions(+)
Added: PKGBUILD
===================================================================
--- PKGBUILD (rev 0)
+++ PKGBUILD 2021-06-04 21:17:56 UTC (rev 955944)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgbase=fcitx5-pinyin-zhwiki
+pkgname=(fcitx5-pinyin-zhwiki rime-pinyin-zhwiki)
+_converterver=0.2.3
+_zhwikiver=20210601
+_webslangver=20210605
+pkgver=$_converterver.$_webslangver
+pkgrel=1
+epoch=1
+pkgdesc="Fcitx 5 Pinyin Dictionary from zh.wikipedia.org"
+arch=('any')
+url="https://github.com/felixonmars/fcitx5-pinyin-zhwiki"
+license=('CCPL:by-sa' 'custom:GFDL')
+makedepends=('libime' 'opencc' 'pypinyin')
+source=(https://github.com/felixonmars/fcitx5-pinyin-zhwiki/archive/$_converterver/$pkgbase-$_converterver.tar.gz
+ https://github.com/felixonmars/fcitx5-pinyin-zhwiki/releases/download/$_converterver/web-slang-$_webslangver.source
+ https://dumps.wikimedia.org/zhwiki/$_zhwikiver/zhwiki-$_zhwikiver-all-titles-in-ns0.gz
+ https://www.gnu.org/licenses/fdl-1.3.txt)
+sha512sums=('b09e4e29e4c3e5e9007f28d56e2ac07663ad56eb1e4004dad647de7f4b41522054a65c40f952bb3752ea6015b3b1adc30f95922749cd5653ea60b9d151dd4013'
+ 'e49d318b36ef0f4d3466feccb3b736ae2e57074d6199339812aa707998fc117fbce4bf88eb348140122520ad56ded1f18e760267d5f2a5c1f774450e1dfb8ed3'
+ 'ad873c977659e321e2cc714a0c2f74877ba3bd970ce14bfcb00907f3b577cc884725248ce5c568187c57a76e676b5b0786e2ddb568a321f170ba517d873f9182'
+ 'bea1788b2bdc84f470e459114b871cf4ee991718964a63e18adde65116806d7676484cb30857cf74dece5eef5f96a015ee4a21900e019623e5d3484868b28b7f')
+
+_make="make -L VERSION=$_zhwikiver WEB_SLANG_VERSION=$_webslangver"
+
+prepare() {
+ cd $pkgbase-$_converterver
+ # Workaround pacman decompression
+ touch zhwiki-$_zhwikiver-all-titles-in-ns0.gz
+ ln -s ../zhwiki-$_zhwikiver-all-titles-in-ns0
+ ln -s ../web-slang-$_webslangver.source
+}
+
+build() {
+ cd $pkgbase-$_converterver
+ $_make zhwiki.dict zhwiki.dict.yaml
+}
+
+package_fcitx5-pinyin-zhwiki() {
+ cd $pkgbase-$_converterver
+ $_make DESTDIR="$pkgdir" install
+ install -Dm644 ../fdl-1.3.txt -t "$pkgdir"/usr/share/licenses/$pkgname/
+}
+
+package_rime-pinyin-zhwiki() {
+ cd $pkgbase-$_converterver
+ $_make DESTDIR="$pkgdir" install_rime_dict
+ install -Dm644 ../fdl-1.3.txt -t "$pkgdir"/usr/share/licenses/$pkgname/
+}
More information about the arch-commits
mailing list