[arch-commits] Commit in kate/repos/extra-x86_64 (PKGBUILD PKGBUILD)

[Antonio Rojas]

    Date: Thursday, June 10, 2021 @ 10:30:45
  Author: arojas
Revision: 417853

archrelease: copy trunk to extra-x86_64

Added:
  kate/repos/extra-x86_64/PKGBUILD
    (from rev 417852, kate/trunk/PKGBUILD)
Deleted:
  kate/repos/extra-x86_64/PKGBUILD

----------+
 PKGBUILD |  111 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 56 insertions(+), 55 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-06-10 10:30:37 UTC (rev 417852)
+++ PKGBUILD	2021-06-10 10:30:45 UTC (rev 417853)
@@ -1,55 +0,0 @@
-# Maintainer: Felix Yan <felixonmars at archlinux.org>
-# Maintainer: Antonio Rojas <arojas at archlinux.org>
-# Contributor: Andrea Scarpino <andrea at archlinux.org>
-
-pkgbase=kate
-pkgname=(kwrite kate)
-pkgver=21.04.1
-pkgrel=1
-arch=(x86_64)
-license=(GPL LGPL FDL)
-makedepends=(extra-cmake-modules kdoctools plasma-framework knewstuff kitemmodels ktexteditor kactivities kuserfeedback)
-source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgbase-$pkgver.tar.xz{,.sig})
-sha256sums=('6264b6c9775caf2e9f7dabdbd7e60d641629e0e8c0ef5abb04dd8bb31ef5a255'
-            'SKIP')
-validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
-              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
-              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
-
-build() {
-  cmake -B build -S $pkgbase-$pkgver \
-    -DBUILD_TESTING=OFF
-  cmake --build build
-}
-
-package_kwrite() {
-  pkgdesc='Text Editor'
-  groups=(kde-applications kde-utilities)
-  url='https://apps.kde.org/kwrite/'
-  depends=(ktexteditor hicolor-icon-theme)
-
-  DESTDIR="$pkgdir" cmake --install build
-
-  find "$pkgdir" -type f -name '*kate*' -exec rm {} \;
-  rm -r "$pkgdir"/usr/lib/qt/plugins/ktexteditor \
-        "$pkgdir"/usr/share/doc/HTML/*/{kate,katepart} \
-        "$pkgdir"/usr/share/katexmltools \
-        "$pkgdir"/usr/share/locale/*/LC_MESSAGES/{ktexteditorpreviewplugin,lspclient,tabswitcherplugin}.mo \
-        "$pkgdir"/usr/share/plasma/plasmoids
-}
-
-package_kate() {
-  pkgdesc='Advanced Text Editor'
-  groups=(kde-applications kde-utilities)
-  url='https://apps.kde.org/kate/'
-  depends=(knewstuff ktexteditor kactivities kuserfeedback hicolor-icon-theme)
-  optdepends=('konsole: open a terminal in Kate'
-              'clang: C and C++ LSP support'
-              'python-language-server: Python LSP support'
-              'texlab: LaTeX LSP support'
-              'rust: Rust LSP support')
-  DESTDIR="$pkgdir" cmake --install build
-
-  find "$pkgdir" -type f -name '*kwrite*' -exec rm {} \;
-  rm -r "$pkgdir"/usr/share/doc/HTML/*/kwrite
-}

Copied: kate/repos/extra-x86_64/PKGBUILD (from rev 417852, kate/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-06-10 10:30:45 UTC (rev 417853)
@@ -0,0 +1,56 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Maintainer: Antonio Rojas <arojas at archlinux.org>
+# Contributor: Andrea Scarpino <andrea at archlinux.org>
+
+pkgbase=kate
+pkgname=(kwrite kate)
+pkgver=21.04.2
+pkgrel=1
+arch=(x86_64)
+license=(GPL LGPL FDL)
+makedepends=(extra-cmake-modules kdoctools plasma-framework knewstuff kitemmodels ktexteditor kactivities kuserfeedback)
+source=(https://download.kde.org/stable/release-service/$pkgver/src/$pkgbase-$pkgver.tar.xz{,.sig})
+sha256sums=('370d75eecbba6740f80e9aff807d3117ff27a4332865acf5351e9e063e0b6d60'
+            'SKIP')
+validpgpkeys=(CA262C6C83DE4D2FB28A332A3A6A4DB839EAA6D7  # Albert Astals Cid <aacid at kde.org>
+              F23275E4BF10AFC1DF6914A6DBD2CE893E2D1C87  # Christoph Feck <cfeck at kde.org>
+              D81C0CB38EB725EF6691C385BB463350D6EF31EF) # Heiko Becker <heiko.becker at kde.org>
+
+build() {
+  cmake -B build -S $pkgbase-$pkgver \
+    -DBUILD_TESTING=OFF
+  cmake --build build
+}
+
+package_kwrite() {
+  pkgdesc='Text Editor'
+  groups=(kde-applications kde-utilities)
+  url='https://apps.kde.org/kwrite/'
+  depends=(ktexteditor hicolor-icon-theme)
+
+  DESTDIR="$pkgdir" cmake --install build
+
+  find "$pkgdir" -type f -name '*kate*' -exec rm {} \;
+  rm -r "$pkgdir"/usr/lib/qt/plugins/ktexteditor \
+        "$pkgdir"/usr/share/doc/HTML/*/{kate,katepart} \
+        "$pkgdir"/usr/share/katexmltools \
+        "$pkgdir"/usr/share/locale/*/LC_MESSAGES/{ktexteditorpreviewplugin,lspclient,tabswitcherplugin}.mo \
+        "$pkgdir"/usr/share/plasma/plasmoids
+}
+
+package_kate() {
+  pkgdesc='Advanced Text Editor'
+  groups=(kde-applications kde-utilities)
+  url='https://apps.kde.org/kate/'
+  depends=(knewstuff ktexteditor kactivities kuserfeedback hicolor-icon-theme)
+  optdepends=('konsole: open a terminal in Kate'
+              'clang: C and C++ LSP support'
+              'python-language-server: Python LSP support'
+              'texlab: LaTeX LSP support'
+              'rust: Rust LSP support'
+              'git: git-blame plugin')
+  DESTDIR="$pkgdir" cmake --install build
+
+  find "$pkgdir" -type f -name '*kwrite*' -exec rm {} \;
+  rm -r "$pkgdir"/usr/share/doc/HTML/*/kwrite
+}