[arch-commits] Commit in radare2/repos (2 files)

[Levente Polyak]

    Date: Saturday, June 12, 2021 @ 00:43:44
  Author: anthraxx
Revision: 963029

archrelease: copy trunk to community-staging-x86_64

Added:
  radare2/repos/community-staging-x86_64/
  radare2/repos/community-staging-x86_64/PKGBUILD
    (from rev 963028, radare2/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: radare2/repos/community-staging-x86_64/PKGBUILD (from rev 963028, radare2/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-06-12 00:43:44 UTC (rev 963029)
@@ -0,0 +1,47 @@
+# Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Guillermo Ramos <0xwille at gmail dot com>
+
+pkgname=radare2
+pkgver=5.3.1
+pkgrel=1
+pkgdesc='Open-source tools to disasm, debug, analyze and manipulate binary files'
+url='https://radare.org'
+arch=('x86_64')
+license=('GPL3' 'LGPL3')
+depends=('sh' 'capstone' 'libcapstone.so' 'openssl' 'libzip' 'zlib'
+         'lz4' 'xxhash' 'libxxhash.so' 'file' 'libuv' 'tree-sitter'
+         'libtree-sitter.so' 'libzip.so' 'libmagic.so')
+makedepends=('meson')
+optdepends=('r2ghidra: ghidra decompiler plugin')
+options=('!emptydirs')
+source=(https://github.com/radare/radare2/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha512sums=('34c96c7c863fb8a59f1d03539375d5b8f31f6021dc84ce943daa163d8a0227bf3156963cc187c366790abec4381da6aa987248e76570a498cfcdeb982cb2ffc0')
+b2sums=('8b29e81c90f477e313f5d14dea707f3e8d47c9abbe1f9ca2c7caef98a85b38a5b5e37a31063be289c55fda041e10b8403895f863dd602091ab5307213605260d')
+
+build() {
+  cd ${pkgname}-${pkgver}
+  touch libr/config.mk
+  arch-meson build \
+    -D use_sys_capstone=true \
+    -D use_capstone_version=v4 \
+    -D use_sys_magic=true \
+    -D use_sys_zip=true \
+    -D use_sys_zlib=true \
+    -D use_sys_lz4=true \
+    -D use_sys_xxhash=true \
+    -D use_sys_openssl=true \
+    -D use_sys_tree_sitter=true \
+    -D use_libuv=true \
+    -D use_webui=true \
+    -D tree-sitter-sync=true
+  ninja -C build
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  DESTDIR="${pkgdir}" ninja -C build install
+  cp -r doc/* "${pkgdir}/usr/share/doc/radare2"
+  ln -s /usr/share/man/man1/radare2.1.gz "${pkgdir}/usr/share/man/man1/r2.1.gz"
+}
+
+# vim: ts=2 sw=2 et: