[arch-commits] Commit in libressl/repos (2 files)

[Levente Polyak]

    Date: Saturday, June 12, 2021 @ 01:16:22
  Author: anthraxx
Revision: 963057

archrelease: copy trunk to community-staging-x86_64

Added:
  libressl/repos/community-staging-x86_64/
  libressl/repos/community-staging-x86_64/PKGBUILD
    (from rev 963056, libressl/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: libressl/repos/community-staging-x86_64/PKGBUILD (from rev 963056, libressl/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-06-12 01:16:22 UTC (rev 963057)
@@ -0,0 +1,56 @@
+# Maintainer: Levente Polyak <anthraxx at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+# Contributor: Maarten de Vries <maarten at de-vri.es>
+# Contributor: Reventlov <contact at volcanis.me>
+# Contributor: kpcyrd <git at rxv.cc>
+
+pkgname=libressl
+pkgver=3.3.3
+pkgrel=1
+pkgdesc="Free version of the TLS/crypto stack forked from OpenSSL"
+arch=(x86_64)
+url="https://www.libressl.org/"
+license=(ISC custom:OpenSSL)
+depends=(glibc)
+optdepends=(ca-certificates)
+backup=(etc/libressl/openssl.cnf)
+source=(https://ftp.openbsd.org/pub/OpenBSD/LibreSSL/libressl-${pkgver}.tar.gz{,.asc})
+sha256sums=('a471565b36ccd1a70d0bd7d37c6e95c43a26a62829b487d9d2cdebfe58be3066'
+            'SKIP')
+validpgpkeys=(A1EB079B8D3EB92B4EBD3139663AF51BD5E4D8D5) # Brent Cook <bcook at openbsd.org>
+
+prepare() {
+    cd ${pkgname}-${pkgver}
+    autoreconf -vfi
+}
+
+build() {
+    cd ${pkgname}-${pkgver}
+    ./configure \
+        --prefix=/usr \
+        --with-openssldir=/etc/libressl \
+        --libdir=/usr/lib/libressl \
+        --includedir=/usr/include/libressl \
+        --program-prefix "libressl-"
+    sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+    make
+}
+
+check() {
+    cd ${pkgname}-${pkgver}
+    make check
+}
+
+package() {
+    cd ${pkgname}-${pkgver}
+    make DESTDIR="${pkgdir}" install
+    install -Dm644 COPYING -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+
+    # Remove symlink man pages, that actually points to OpenSSL ones since the prefix is not accounted for
+    for manlink in $(find -L "${pkgdir}"/usr/share/man/man3/ -type l) ;
+    do
+        rm "${manlink}" ;
+    done
+}
+
+# vim: ts=4 sw=4 et: