[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, June 14, 2021 @ 16:50:30
  Author: felixonmars
Revision: 963482

addpkg: haskell-hls-module-name-plugin 1.0.0.0-1

Added:
  haskell-hls-module-name-plugin/
  haskell-hls-module-name-plugin/repos/
  haskell-hls-module-name-plugin/trunk/
  haskell-hls-module-name-plugin/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: haskell-hls-module-name-plugin/trunk/PKGBUILD
===================================================================
--- haskell-hls-module-name-plugin/trunk/PKGBUILD	                        (rev 0)
+++ haskell-hls-module-name-plugin/trunk/PKGBUILD	2021-06-14 16:50:30 UTC (rev 963482)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-module-name-plugin
+pkgname=haskell-hls-module-name-plugin
+pkgver=1.0.0.0
+pkgrel=1
+pkgdesc="Module name plugin for Haskell Language Server"
+url="https://hackage.haskell.org/package/hls-module-name-plugin"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ghcide' 'haskell-hls-plugin-api' 'haskell-lsp'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'uusi' 'haskell-hls-test-utils')
+checkdepends=('git')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('abcf1d52aa552b97e459c0e8c70af03f8428e292c253dcd14eea753283fd81a8')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}