[arch-commits] Commit in haskell-hls-class-plugin/repos (2 files)

[Felix Yan]

    Date: Tuesday, June 15, 2021 @ 17:45:21
  Author: felixonmars
Revision: 963932

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hls-class-plugin/repos/community-staging-x86_64/
  haskell-hls-class-plugin/repos/community-staging-x86_64/PKGBUILD
    (from rev 963931, haskell-hls-class-plugin/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-hls-class-plugin/repos/community-staging-x86_64/PKGBUILD (from rev 963931, haskell-hls-class-plugin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-06-15 17:45:21 UTC (rev 963932)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-class-plugin
+pkgname=haskell-hls-class-plugin
+pkgver=1.0.0.2
+pkgrel=2
+pkgdesc="Class/instance management plugin for Haskell Language Server"
+url="https://github.com/haskell/haskell-language-server#readme"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ghc' 'haskell-ghc-api-compat' 'haskell-ghc-exactprint'
+         'haskell-ghcide' 'haskell-hls-plugin-api' 'haskell-lens' 'haskell-lsp')
+makedepends=('ghc' 'uusi' 'haskell-hls-test-utils' 'haskell-lsp-types')
+checkdepends=('git')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('cc316f581a975ec282c5463d522180b4401b0e154eeae1e333acaeeb77af80163b95bfb5796111026763557fc59d83d44455ed185290504182e1234a8547150f')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}