[arch-commits] Commit in haskell-hls-tactics-plugin/repos (2 files)

[Felix Yan]

    Date: Tuesday, June 15, 2021 @ 20:56:56
  Author: felixonmars
Revision: 964173

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hls-tactics-plugin/repos/community-staging-x86_64/
  haskell-hls-tactics-plugin/repos/community-staging-x86_64/PKGBUILD
    (from rev 964172, haskell-hls-tactics-plugin/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: haskell-hls-tactics-plugin/repos/community-staging-x86_64/PKGBUILD (from rev 964172, haskell-hls-tactics-plugin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-06-15 20:56:56 UTC (rev 964173)
@@ -0,0 +1,56 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-tactics-plugin
+pkgname=haskell-hls-tactics-plugin
+pkgver=1.2.0.0
+pkgrel=3
+pkgdesc="Wingman plugin for Haskell Language Server"
+url="https://haskellwingman.dev"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-extra' 'haskell-fingertree' 'haskell-generic-lens'
+         'haskell-ghc' 'haskell-ghc-exactprint' 'haskell-ghc-source-gen' 'haskell-ghcide'
+         'haskell-hls-graph' 'haskell-hls-plugin-api' 'haskell-hyphenation' 'haskell-lens'
+         'haskell-lsp' 'haskell-megaparsec' 'haskell-parser-combinators' 'haskell-prettyprinter'
+         'haskell-refinery' 'haskell-retrie' 'haskell-syb' 'haskell-unordered-containers')
+makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-hls-test-utils' 'haskell-hspec'
+             'haskell-hspec-discover' 'haskell-hspec-expectations' 'haskell-lsp-types'
+             'haskell-tasty-hunit' 'haskell-tasty-hspec')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('c007db78386e04f735bd09801c226e7d79bdcc9c4d863aa5940e15136a94152f88e10c9a77a32c92725174342bda3b0708a9e550146c893f35693a7a6b389fe1')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  gen-setup
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}