[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Wednesday, June 16, 2021 @ 18:32:38
  Author: felixonmars
Revision: 964304

addpkg: haskell-html-parse 0.2.0.2-1

Added:
  haskell-html-parse/
  haskell-html-parse/repos/
  haskell-html-parse/trunk/
  haskell-html-parse/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: haskell-html-parse/trunk/PKGBUILD
===================================================================
--- haskell-html-parse/trunk/PKGBUILD	                        (rev 0)
+++ haskell-html-parse/trunk/PKGBUILD	2021-06-16 18:32:38 UTC (rev 964304)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=html-parse
+pkgname=haskell-html-parse
+pkgver=0.2.0.2
+pkgrel=1
+pkgdesc="A high-performance HTML tokenizer"
+url="http://github.com/bgamari/html-parse"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-attoparsec')
+makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-hspec' 'haskell-hspec-discover'
+             'haskell-quickcheck-instances' 'haskell-string-conversions')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('683cff893e5079bcf4d611d0939f04237abd03f5bf8dbc9e3f88e19c6938a736')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -u base -u attoparsec $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}