[arch-commits] Commit in virtualbox-host-modules-arch/repos (2 files)

[Jan Steffens]

    Date: Wednesday, June 16, 2021 @ 22:14:38
  Author: heftig
Revision: 964363

archrelease: copy trunk to community-testing-x86_64

Added:
  virtualbox-host-modules-arch/repos/community-testing-x86_64/
  virtualbox-host-modules-arch/repos/community-testing-x86_64/PKGBUILD
    (from rev 964361, virtualbox-host-modules-arch/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: virtualbox-host-modules-arch/repos/community-testing-x86_64/PKGBUILD (from rev 964361, virtualbox-host-modules-arch/trunk/PKGBUILD)
===================================================================
--- community-testing-x86_64/PKGBUILD	                        (rev 0)
+++ community-testing-x86_64/PKGBUILD	2021-06-16 22:14:38 UTC (rev 964363)
@@ -0,0 +1,39 @@
+# Maintainer: Sébastien Luttringer
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname='virtualbox-host-modules-arch'
+pkgver=6.1.22
+pkgrel=17
+pkgdesc='Virtualbox host kernel modules for Arch Kernel'
+arch=('x86_64')
+url='https://virtualbox.org/'
+license=('GPL')
+makedepends=('linux-headers' "virtualbox-host-dkms=$pkgver")
+replaces=('virtualbox-modules' 'virtualbox-host-modules')
+conflicts=('virtualbox-modules' 'virtualbox-host-modules'
+           'virtualbox-host-dkms')
+provides=('VIRTUALBOX-HOST-MODULES')
+
+build() {
+  _kernver="$(</usr/src/linux/version)"
+
+  fakeroot dkms build --dkmstree "$srcdir" -m vboxhost/${pkgver}_OSE -k ${_kernver}
+}
+
+package(){
+  depends=('linux')
+
+  _kernver="$(</usr/src/linux/version)"
+
+  install -Dt "$pkgdir/usr/lib/modules/$_kernver/extramodules" -m0644 \
+    vboxhost/${pkgver}_OSE/${_kernver}/${CARCH}/module/*
+
+  # compress each module individually
+  find "$pkgdir" -name '*.ko' -exec xz -T1 {} +
+
+  # systemd module loading
+  printf '%s\n' vboxdrv vboxnetadp vboxnetflt |
+    install -D -m0644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"
+}
+
+