[arch-commits] Commit in haskell-containers-unicode-symbols/repos (2 files)

[Felix Yan]

    Date: Wednesday, June 16, 2021 @ 23:54:42
  Author: felixonmars
Revision: 964437

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-containers-unicode-symbols/repos/community-staging-x86_64/
  haskell-containers-unicode-symbols/repos/community-staging-x86_64/PKGBUILD
    (from rev 964436, haskell-containers-unicode-symbols/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: haskell-containers-unicode-symbols/repos/community-staging-x86_64/PKGBUILD (from rev 964436, haskell-containers-unicode-symbols/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-06-16 23:54:42 UTC (rev 964437)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=containers-unicode-symbols
+pkgname=haskell-containers-unicode-symbols
+pkgver=0.3.1.3
+pkgrel=2
+pkgdesc="Unicode alternatives for common functions and operators"
+url="https://haskell.org/haskellwiki/Unicode-symbols"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-unicode-symbols')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('7294ebe2b85fddfac94d2d1e990722793d8d8e88ff1efb9d35394748ef5b05db132e42be3cce1d75b5f5b1ba97c6c2e75cb1f0b0d9c2e88dbed227094bfda5ea')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-containers-old
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}