[arch-commits] Commit in (4 files)

[Fabio Castelli]

    Date: Sunday, June 20, 2021 @ 12:11:44
  Author: muflone
Revision: 965886

new package perl-goocanvas2-cairotypes (needed as dependency for shutter)

Added:
  perl-goocanvas2-cairotypes/
  perl-goocanvas2-cairotypes/repos/
  perl-goocanvas2-cairotypes/trunk/
  perl-goocanvas2-cairotypes/trunk/PKGBUILD

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Added: perl-goocanvas2-cairotypes/trunk/PKGBUILD
===================================================================
--- perl-goocanvas2-cairotypes/trunk/PKGBUILD	                        (rev 0)
+++ perl-goocanvas2-cairotypes/trunk/PKGBUILD	2021-06-20 12:11:44 UTC (rev 965886)
@@ -0,0 +1,45 @@
+# Maintainer: Muflone http://www.muflone.com/contacts/english/
+# Contributor: PhotonX <michael dot kogan at gmx dot net>
+
+pkgname=perl-goocanvas2-cairotypes
+_perl_module=GooCanvas2-CairoTypes
+pkgver=0.001
+pkgrel=4
+pkgdesc="Bridge between GooCanvas2 and Cairo types"
+arch=('x86_64')
+url="https://metacpan.org/release/${_perl_module}"
+license=('PerlArtistic' 'GPL')
+depends=('goocanvas' 'perl-gtk3')
+makedepends=('perl-extutils-depends' 'perl-extutils-pkgconfig')
+source=("https://cpan.metacpan.org/authors/id/A/AS/ASOKOLOV/${_perl_module}-${pkgver}.tar.gz")
+sha256sums=('ba806736ebcc9de3d8141a763a682bdeabb1cb8702bde299adfd574ace875052')
+options=('!emptydirs')
+
+prepare() {
+  cd "${_perl_module}-${pkgver}"
+  sed -i "s/goocanvas-2.0/goocanvas-3.0/" Makefile.PL
+}
+
+
+build() {
+  cd "${_perl_module}-${pkgver}"
+  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
+  export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
+  perl Makefile.PL
+  make
+}
+
+check() {
+  cd "${_perl_module}-${pkgver}"
+  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
+  export PERL_MM_USE_DEFAULT=1
+  make test
+}
+
+package() {
+  cd "${_perl_module}-${pkgver}"
+  unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
+  make pure_install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
+  # Delete unuseful files
+  find "${pkgdir}" -name '.packlist' -delete
+}